CIL (tên riêng của MSIL) và mã bytecode của Java giống nhau hơn là chúng khác nhau. Tuy nhiên, có một số khác biệt quan trọng:
1) CIL được thiết kế ngay từ đầu để phục vụ như một mục tiêu cho nhiều ngôn ngữ. Do đó, nó hỗ trợ một hệ thống kiểu phong phú hơn nhiều bao gồm các kiểu có dấu và không dấu, kiểu giá trị, con trỏ, thuộc tính, đại biểu, sự kiện, tổng thể, hệ thống đối tượng có một gốc duy nhất, v.v. CIL hỗ trợ các tính năng không cần thiết cho các ngôn ngữ CLR ban đầu (C # và VB.NET) chẳng hạn như các chức năng toàn cục và tối ưu hóa cuộc gọi đuôi . Để so sánh, Java bytecode được thiết kế như một mục tiêu cho ngôn ngữ Java và phản ánh nhiều ràng buộc được tìm thấy trong chính Java. Sẽ khó hơn rất nhiều để viết C hoặc Scheme bằng Java bytecode.
2) CIL được thiết kế để tích hợp dễ dàng vào các thư viện gốc và mã không được quản lý
3) Mã bytecode của Java được thiết kế để có thể thông dịch hoặc biên dịch trong khi CIL được thiết kế với giả định chỉ biên dịch JIT. Điều đó nói rằng, việc triển khai Mono ban đầu sử dụng một trình thông dịch thay vì một JIT.
4) CIL được thiết kế ( và được chỉ định ) để có một dạng ngôn ngữ hợp ngữ có thể đọc và ghi được của con người, ánh xạ trực tiếp tới dạng bytecode. Tôi tin rằng mã bytecode của Java (như tên của nó) có nghĩa là chỉ máy có thể đọc được. Tất nhiên, Java bytecode tương đối dễ dàng được dịch ngược trở lại Java gốc và như hình dưới đây, nó cũng có thể được "tháo rời".
Tôi nên lưu ý rằng JVM (hầu hết trong số chúng) được tối ưu hóa cao hơn CLR (bất kỳ trong số chúng). Vì vậy, hiệu suất thô có thể là một lý do để thích nhắm mục tiêu theo mã byte Java. Đây là một chi tiết thực hiện mặc dù.
Một số người nói rằng mã bytecode của Java được thiết kế để đa nền tảng trong khi CIL được thiết kế chỉ dành cho Windows. Đây không phải là trường hợp. Có một số isms "Windows" trong .NET framework nhưng không có trong CIL.
Như ví dụ của điểm số 4) ở trên, tôi đã viết một trình biên dịch Java sang CIL đồ chơi một thời gian trước. Nếu bạn cung cấp trình biên dịch này chương trình Java sau:
class Factorial{
public static void main(String[] a){
System.out.println(new Fac().ComputeFac(10));
}
}
class Fac {
public int ComputeFac(int num){
int num_aux ;
if (num < 1)
num_aux = 1 ;
else
num_aux = num * (this.ComputeFac(num-1)) ;
return num_aux ;
}
}
trình biên dịch của tôi sẽ tạo ra CIL sau:
.assembly extern mscorlib { }
.assembly 'Factorial' { .ver 0:0:0:0 }
.class private auto ansi beforefieldinit Factorial extends [mscorlib]System.Object
{
.method public static default void main (string[] a) cil managed
{
.entrypoint
.maxstack 16
newobj instance void class Fac::'.ctor'()
ldc.i4 3
callvirt instance int32 class Fac::ComputeFac (int32)
call void class [mscorlib]System.Console::WriteLine(int32)
ret
}
}
.class private Fac extends [mscorlib]System.Object
{
.method public instance default void '.ctor' () cil managed
{
ldarg.0
call instance void object::'.ctor'()
ret
}
.method public int32 ComputeFac(int32 num) cil managed
{
.locals init ( int32 num_aux )
ldarg num
ldc.i4 1
clt
brfalse L1
ldc.i4 1
stloc num_aux
br L2
L1:
ldarg num
ldarg.0
ldarg num
ldc.i4 1
sub
callvirt instance int32 class Fac::ComputeFac (int32)
mul
stloc num_aux
L2:
ldloc num_aux
ret
}
}
Đây là một chương trình CIL hợp lệ có thể được đưa vào một trình hợp dịch CIL như ilasm.exeđể tạo một tệp thực thi. Như bạn có thể thấy, CIL là một ngôn ngữ hoàn toàn có thể đọc và ghi được của con người. Bạn có thể dễ dàng tạo các chương trình CIL hợp lệ trong bất kỳ trình soạn thảo văn bản nào.
Bạn cũng có thể biên dịch chương trình Java ở trên bằng javactrình biên dịch và sau đó chạy các tệp lớp kết quả thông qua javap"trình tháo gỡ" để có được những điều sau:
class Factorial extends java.lang.Object{
Factorial();
Code:
0: aload_0
1: invokespecial #1;
4: return
public static void main(java.lang.String[]);
Code:
0: getstatic #2;
3: new #3;
6: dup
7: invokespecial #4;
10: bipush 10
12: invokevirtual #5;
15: invokevirtual #6;
18: return
}
class Fac extends java.lang.Object{
Fac();
Code:
0: aload_0
1: invokespecial #1;
4: return
public int ComputeFac(int);
Code:
0: iload_1
1: iconst_1
2: if_icmpge 10
5: iconst_1
6: istore_2
7: goto 20
10: iload_1
11: aload_0
12: iload_1
13: iconst_1
14: isub
15: invokevirtual #2;
18: imul
19: istore_2
20: iload_2
21: ireturn
}
Đầu javapra không thể biên dịch được (theo hiểu biết của tôi) nhưng nếu bạn so sánh nó với đầu ra CIL ở trên, bạn có thể thấy rằng cả hai rất giống nhau.