hoàn thành tab zsh trên dòng trống

Tôi muốn một tcsh'ism mà tôi không thể tìm thấy: Trên một dòng trống không có nội dung, tôi muốn nhấn phím tab và xem tương đương với một ls. Đó là để nói rằng tôi muốn

$ <tab>

để làm một cái gì đó khác sau đó cho tôi một \ t. Tôi đã tìm thấy các tài nguyên tuyệt vời để hoàn thành lệnh, nhưng không phải cho trường hợp cơ sở này. Bất kỳ trợ giúp về điều này sẽ là tuyệt vời! Cảm ơn.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Hành vi của Tabở đầu một dòng được kiểm soát bởi phong cách . Tuy nhiên, chỉ có hai hành vi được hỗ trợ:insert-tab

• hoàn thành như bình thường, dưới zstyle ':completion:*' insert-tab false
• chèn một tab, bên dưới zstyle ':completion:*' insert-tab true
• một trong hai hoặc dưới zstyle ':completion:*' insert-tab pending[=N]

Nếu bạn chỉ muốn hoàn thành các lệnh ở vị trí đó, zstyle ':completion:*' insert-tab truesẽ làm. Nếu bạn muốn một cái gì đó khác nhau, như liệt kê các tệp trong thư mục hiện tại, bạn sẽ cần phải sửa đổi _main_complete.

Một chủ đề gần đây trong danh sách zsh-worker đã thảo luận insert-tab.

Dưới đây là thực hiện đầy đủ tính năng tự động của tcsh trong zsh, khi bạn nhấn tab trên dòng trống

% <TAB>

Đây là:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Nếu bạn muốn mô phỏng tcsh chặt chẽ hơn, hãy thêm phần này vào .zshrc của bạn:

unsetopt always_last_prompt       # print completion suggestions above prompt

Tôi đã viết tiện ích zsh này giúp tăng cường sử dụng TAB, không chỉ trên một dòng trống mà còn trong khi bạn đang gõ một lệnh.

• Nó sẽ liệt kê các tập tin trên một dòng lệnh trống và ở giữa bất kỳ lệnh nào.
• Nó sẽ liệt kê các thư mục trên một dòng lệnh trống.
• Nó sẽ liệt kê các tệp thực thi trên một dòng lệnh trống.

Nó có thể được cấu hình để thêm vào "cd" hoặc "./" trong những trường hợp có biến toàn cục.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA