chúng ta có thể in từ cuối cùng của mỗi dòng trong linux bằng lệnh sed không?

giả sử, nếu có một tập tin bao gồm các dòng sau, nếu chúng là

12345 567 7878 66

   er3 t45t y6y46y 


 4y6 y656y y5y

   46y6 65y7 y66uyuy

 yy46y6y

Đầu ra phải giống như:

66

y6y46y

y5y

y66uyuyy

y46y6y

Tôi đã thử sed 's/.* //g'tên tệp và một số sedlệnh khác , nhưng nó không hoạt động.

Tôi có thể biết sedlệnh chính xác là gì?

awk '{print $NF}'
sed 's/[[:blank:]]*$//;s/.*[[:blank:]]//'

Điều đó vẫn sẽ in một dòng trống cho mỗi dòng trống. Để tránh nó:

awk 'NF{print $NF}'
sed 's/[[:blank:]]*$//;s/.*[[:blank:]]//;/./!d'

Các awkbiến $NFlà trường cuối cùng của tất cả các kỷ lục ; bạn chỉ có thể sử dụng nó để in các trường cuối cùng của tệp như vậy:

awk '{print $NF}' file

Bạn co thể thử :

• sed 's/.* //'
• awk '{print $NF}'

Bạn đã gần tới. Chỉ cần xác định từ cuối cùng:

sed 's/^.* \([^ ][^ ]*\)/\1/g'

Những gì nó làm:

1. '^. *' xóa mọi thứ trong đầu dòng và mọi khoảng trắng.
2. '\ (...) \' khớp với mẫu và trả về là \ 1.
3. '[^]' Phù hợp với mọi thứ mà không có khoảng trắng trong đó.

(Đã chỉnh sửa để thêm giải pháp tốt hơn. Cảm ơn Hildred!)

Bạn có thể sử dụng một số mô hình đầy đủ grepthay vì sed, ví dụ:

grep -o "[a-Z0-9]*$"

Trong ví dụ này, [...]phạm vi chứa các ký tự được coi là phù hợp cho một "từ" (chữ số trong trường hợp này, các ký hiệu khác có thể được thêm vào, một số ký tự phải được thoát).

Nếu bạn đủ điều kiện từ có nghĩa là bất kỳ chuỗi của 1 hoặc nhiều phi trống ký tự thì câu trả lời chắc chắn là có, và nó rất đơn giản được thực hiện là tốt. Điều này là do [[:blank:]]*và [^[:blank:]]*là bổ sung boolean và - miễn là tất cả các ký tự trong một chuỗi hoàn tất - [[:blank:]]*U [^[:blank:]]*có thể mô tả bất kỳ chuỗi nào có thể theo cách tương tự .*.

Nếu một ký tự không đầy đủ hoặc chuỗi byte không hợp lệ tồn tại trong một chuỗi thì không thể mô tả thành công nó từ đầu đến cuối - như đôi khi có thể xảy ra khi diễn giải một chuỗi trong mã hóa sai. Để đảm bảo một ký tự hoàn chỉnh trên mỗi byte trong bất kỳ chuỗi nào, ngôn ngữ C có thể được buộc như sau:

LC_ALL=C sed ...

... sẽ tránh mọi vấn đề mô tả chuỗi từ đầu đến đuôi với một mẫu bao gồm tất cả, chẳng hạn như .*hoặc([ ]*[^ ]*)*

Một mô hình bổ sung đầy đủ có thể lặp lại nhiều lần khi cần thiết từ trái sang phải độ dài của bất kỳ chuỗi nào để hạ cánh ở lần xuất hiện cuối cùng mà không có bất kỳ sự phá vỡ nào trong mẫu. Đây là, chắc chắn, ngôn ngữ thường xuyên.

BRE:

sed 's/\(\([^[:blank:]]*\)[[:blank:]]*\)*/\2/'

ERE:

sed -E 's/(([^[:blank:]]*)[[:blank:]]*)*/\2/'

Cả hai phiên bản này vẫn sẽ in các dòng trống và điều này là do *ngôi sao Kleene khớp với 0 hoặc nhiều lần xuất hiện của một mẫu. Đầu tiên, nó khớp với 0 hoặc nhiều hơn các ký tự trống, sau đó là 0 hoặc nhiều ký tự trống, sau đó là 0 hoặc nhiều lần xuất hiện của các kết quả khớp nhóm cho đến khi nó khớp toàn bộ chuỗi.

Đã khớp với tất cả những điều này, phép màu xảy ra trong sự thay thế - các tham chiếu được trả về bởi các nhóm \1và \2là lần xuất hiện cuối cùng của mỗi nhóm. Vì vậy, khi thay thế được thực hiện, tất cả các chuỗi được thay thế chỉ với lần xuất hiện cuối cùng trên một dòng bằng 0 hoặc nhiều hơn các ký tự trống - hoặc nhóm con \2.

Tất nhiên, điều này hoạt động cho bất kỳ chuỗi nào có thể - ngay cả một chuỗi trống - có nghĩa là cả hai biểu mẫu sẽ in các ký tự dòng mới cho các dòng chỉ chứa các ký tự trống hoặc không có ký tự nào cả. Để xử lý việc này, có một vài điều bạn có thể làm, nhưng trước tiên hãy làm cho lớp nhân vật dễ nhập hơn một chút:

b='[:blank:]'

Bây giờ, chỉ in nếu một dòng chứa một hoặc nhiều ký tự trống bạn có thể làm:

BRE:

sed -n "s/\(\([^$b]*\)[$b]*\)*/\2/;/./p"

ERE:

sed -En "/[^$b]/s/(([^$b]*)[$b]*)*/\2/p"

1. Trường hợp BRE - sự thay thế luôn được thực hiện và chỉ các không gian mẫu có ít nhất một ký tự còn lại được in.
2. Trường hợp ERE - sự thay thế chỉ được thử trên một không gian mẫu có chứa ít nhất một char không trống.

Một trong hai hình thức sẽ hoạt động với một trong hai phương thức - miễn là cú pháp đúng.

Công -ntắc vô hiệu hóa tự động in không gian mẫu và pcờ vào s///ubstlation hoặc các lệnh /địa chỉ chỉ /in kết quả của nó nếu thành công.

Logic tương tự này cũng có thể được áp dụng để có được bất kỳ {num}sự xuất hiện nào, như, như:

BRE:

sed -n "s/\([$b]*\([^$b]\{1,\}\)\)\{num\}.*/\2/p"

ERE:

sed -En "s/([$b]*([^$b]+)){num}.*/\2/p"

... Trong đó numcả hai biểu thức chính có thể được thay thế bằng một số để chỉ in {num}lần xuất hiện được chỉ định của một chuỗi các ký tự không trống. Một hình thức hơi khác nhau được sử dụng ở đây để đảm bảo số lượng không bị sai lệch cho không gian hàng đầu trong một chuỗi.

Lưu ý rằng -EERE chuyển sang sedđược hỗ trợ trong cả BSD và các phiên bản GNU, mặc dù nó không phải là chưa POSIX cú pháp chuẩn.

Đúng. Lệnh sed sau đây trước tiên loại bỏ tất cả các khoảng trắng theo sau ( s/ *$//) và sau đó mọi thứ lên đến và bao gồm cả khoảng trắng cuối cùng ( s/.* //). Có lẽ đáng để thay thế khoảng trắng theo nghĩa đen bằng [[:blank:]]cách chụp các tab và các ký tự giống như không gian khác.

$ echo "  aaa bbb cc   " | sed -e 's/ *$//' -e 's/.* //'
cc
$ echo "  aaa bbb cc" | sed -e 's/ *$//' -e 's/.* //'
cc
$ echo "aaa bbb cc   " | sed -e 's/ *$//' -e 's/.* //'
cc
$ echo "aaa bbb cc" | sed -e 's/ *$//' -e 's/.* //'
cc
$ echo "  cc  " | sed -e 's/ *$//' -e 's/.* //'
cc
$ echo "cc" | sed -e 's/ *$//' -e 's/.* //'
cc

cat file_name | rev | cut -f1 -d ' ' | rev