Làm thế nào để có được dữ liệu theo dõi của kho lưu trữ gzip?

Tôi có một kho lưu trữ gzip với dữ liệu theo dõi. Nếu tôi giải nén nó bằng cách sử dụng gzip -dnó sẽ cho tôi biết: " giải nén OK, bỏ qua rác " (tương tự như vậy gzip -tcó thể được sử dụng như một phương pháp phát hiện ra rằng có dữ liệu đó).

Bây giờ tôi muốn biết về rác này, nhưng thật kỳ lạ là tôi không thể tìm ra cách nào để giải nén nó. gzip -l --verbosecho tôi biết rằng kích thước "nén" của kho lưu trữ là kích thước của tệp (nghĩa là với dữ liệu theo dõi), điều đó sai và không hữu ích. filecũng không giúp được gì, vậy tôi có thể làm gì?

Tìm hiểu làm thế nào để có được dữ liệu theo dõi.

Tôi đã tạo tập lệnh Perl để tạo một tệp có dữ liệu theo dõi, nó dựa rất nhiều vào https://bugs.debian.org/cgi-bin/ormsreport.cgi?orms=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}