Tôi sử dụng bindkey -v(đối với bash-ers set -o vitôi nghĩ rằng nó cũng hoạt động ở chế độ zsh) hoặc vi (m). nhưng điều đó làm tôi bực mình rằng tôi không có bất kỳ dấu hiệu trực quan nào để cho tôi biết tôi đang ở chế độ chèn hay chế độ lệnh. Có ai biết làm thế nào tôi có thể làm cho lời nhắc của tôi hiển thị chế độ?

Tôi tìm thấy điều này thông qua SU . Đây là ví dụ cơ bản, mặc dù tôi vẫn đang tùy chỉnh nó cho chính mình:

function zle-line-init zle-keymap-select {
    RPS1="${${KEYMAP/vicmd/-- NORMAL --}/(main|viins)/-- INSERT --}"
    RPS2=$RPS1
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

Tôi sẽ giải thích nó ngoại trừ tôi chưa thực sự hiểu nó

Bạn đã tìm thấy zle-keymap-selectđược thực thi bất cứ khi nào chế độ thay đổi. Bạn có thể sử dụng nó để đặt một số chỉ báo trực quan khác ngoài lời nhắc, tùy thuộc vào thiết bị đầu cuối của bạn hỗ trợ nó (và sở thích của bạn trong hiển thị chỉ báo chế độ, tất nhiên).

Có một khả năng terminfo tiêu chuẩn để thay đổi hình dạng của con trỏ. Tuy nhiên, một số thiết bị đầu cuối hiển thị cùng một con trỏ trong cả hai chế độ. Khái niệm của Xterm về một con trỏ ít nhìn thấy hơn là làm cho nó nhấp nháy (và điều này phải được kích hoạt với -bcđối số hoặc cursorBlinktài nguyên dòng lệnh ).

zle-keymap-select () {
  case $KEYMAP in
    vicmd) print -rn -- $terminfo[cvvis];; # block cursor
    viins|main) print -rn -- $terminfo[cnorm];; # less visible cursor
  esac
}

Với một số thiết bị đầu cuối, bạn cũng có thể thay đổi màu con trỏ bằng print -n '\e]12;pink\a'(theo tên màu) hoặc print -n '\e]12;#abcdef\a'(theo thông số RGB). Các trình tự này được mô tả trong tài liệu xterm, trong ctlseqstệp; trình giả lập thiết bị đầu cuối hiện đại thường mô phỏng xterm, mặc dù chúng có thể không hỗ trợ tất cả các tính năng của nó.

Đối với những người gặp vấn đề khi sử dụng dấu nhắc đặt lại với lời nhắc đa dòng, cách này hiệu quả với tôi: http://zeitlens.com/posts/2014-06-29-howto-zsh-vi-style.html Kết hợp với https: // stackoverflow.com/questions/3622943/zsh-vi-mode-status-line Tôi đã kết thúc việc làm:

terminfo_down_sc=$terminfo[cud1]$terminfo[cuu1]$terminfo[sc]$terminfo[cud1]

function insert-mode () { echo "-- INSERT --" }
function normal-mode () { echo "-- NORMAL --" }

precmd () {
    # yes, I actually like to have a new line, then some stuff and then 
    # the input line
    print -rP "
[%D{%a, %d %b %Y, %H:%M:%S}] %n %{$fg[blue]%}%m%{$reset_color%}"

    # this is required for initial prompt and a problem I had with Ctrl+C or
    # Enter when in normal mode (a new line would come up in insert mode,
    # but normal mode would be indicated)
    PS1="%{$terminfo_down_sc$(insert-mode)$terminfo[rc]%}%~ $ "
}
function set-prompt () {
    case ${KEYMAP} in
      (vicmd)      VI_MODE="$(normal-mode)" ;;
      (main|viins) VI_MODE="$(insert-mode)" ;;
      (*)          VI_MODE="$(insert-mode)" ;;
    esac
    PS1="%{$terminfo_down_sc$VI_MODE$terminfo[rc]%}%~ $ "
}

function zle-line-init zle-keymap-select {
    set-prompt
    zle reset-prompt
}
preexec () { print -rn -- $terminfo[el]; }

zle -N zle-line-init
zle -N zle-keymap-select

bạn có thể thử VimMode

Đây là những gì tôi sử dụng để thay đổi con trỏ giữa hình dạng 'Chặn' và 'Chùm' trong zsh:

(Đã thử nghiệm với Mối , gnome-terminal và mate-terminal )

# vim mode config
# ---------------

# Activate vim mode.
bindkey -v

# Remove mode switching delay.
KEYTIMEOUT=5

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'

  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select

# Use beam shape cursor on startup.
echo -ne '\e[5 q'

# Use beam shape cursor for each new prompt.
preexec() {
   echo -ne '\e[5 q'
}

Một giải pháp khác để thay đổi hình dạng con trỏ giữa I-tia và khối (đối với dấu gạch dưới, sử dụng \033[4 q). Thêm phần này vào bạn ~/.zshrc.

zle-keymap-select () {
if [ $KEYMAP = vicmd ]; then
    printf "\033[2 q"
else
    printf "\033[6 q"
fi
}
zle -N zle-keymap-select
zle-line-init () {
zle -K viins
printf "\033[6 q"
}
zle -N zle-line-init
bindkey -v

Được sửa đổi từ https://bbs.archlinux.org/viewtopic.php?id=95078 . Đã thử nghiệm trong gnome-terminal 3.22.

Cập nhật

Một giải pháp khác để thay đổi hình dạng con trỏ có thể được tìm thấy ở đây . Cái này rõ ràng hoạt động cho iTerm2, cái mà tôi không có phương tiện để kiểm tra, nhưng thêm nó vào đây trong trường hợp nó hữu ích cho người khác. Sự bổ sung cuối cùng cho bạn ~/.zshrcsẽ là

function zle-keymap-select zle-line-init
{
    # change cursor shape in iTerm2
    case $KEYMAP in
        vicmd)      print -n -- "\E]50;CursorShape=0\C-G";;  # block cursor
        viins|main) print -n -- "\E]50;CursorShape=1\C-G";;  # line cursor
    esac

    zle reset-prompt
    zle -R
}

function zle-line-finish
{
    print -n -- "\E]50;CursorShape=0\C-G"  # block cursor
}

zle -N zle-line-init
zle -N zle-line-finish
zle -N zle-keymap-select

Tôi hiện đang sử dụng Zsh với chủ đề Bullet Train . Theo ví dụ được đưa ra bởi câu trả lời của Sebastian Blask , tôi đã kết thúc với mã dưới đây

bindkey -v
KEYTIMEOUT=1

function zle-line-init zle-keymap-select {
    case ${KEYMAP} in
        (vicmd)      BULLETTRAIN_PROMPT_CHAR="N" ;;
        (main|viins) BULLETTRAIN_PROMPT_CHAR="I" ;;
        (*)          BULLETTRAIN_PROMPT_CHAR="I" ;;
    esac
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

Điều này sẽ chỉ thay đổi de mặc định $ thành chữ N thành chế độ bình thường và tôi sang chế độ chèn.

Hình ảnh này là một ví dụ khi ở chế độ bình thường tôi nhấn Ctrl+ C:

Đây là một phiên bản khác, dựa trên bài viết của Sebastian Blask . Điều này được dự định là không xâm phạm nhất có thể, vì tất cả các giải pháp khác tôi có thể tìm thấy đã sử dụng thêm dòng, trạng thái ở bên phải hoặc thêm ký tự.

Điều này chỉ đơn giản là thay đổi màu $từ trắng sang đỏ khi bật chế độ bình thường. Chỉnh sửa lời nhắc theo ý thích của bạn

bindkey -v
function zle-line-init zle-keymap-select {
    case ${KEYMAP} in
        (vicmd)      PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} %{\e[0;31m%}$%{\e[0m%} ' ;;
        (main|viins) PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} $ ' ;;
        (*)          PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} $ ' ;;
    esac
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

Một phiên bản cho oh-my-zshngười dùng

Có một plugin để oh-my-zshgọi vi-modecó thể được tìm thấy ở đây:

robbyrussell / oh-my-zsh / plugin / vi-mode

Tôi sử dụng Antigen để quản lý các plugin của mình, vì vậy việc bao gồm nó cũng đơn giản như việc thêm nó vào .zshrc:

antigen bundle vi-mode

Các zsh-vim-mode plugin là có thể hiển thị một chỉ báo cho chèn, lệnh, tìm kiếm, thay thế, và phương thức thị giác. Nó sử dụng kỹ thuật cơ bản của các câu trả lời khác để nối vào các móc ZLE khác nhau (zle-keymap-select, zle-isearch-update, v.v.). Nó kiểm tra [[ $ZLE_STATE = *overwrite* ]]chế độ thay thế. Nó kiểm tra $REGION_ACTIVEđể xác định chế độ trực quan.

Logic rất phức tạp bởi một số câu hỏi về cách ZSH kích hoạt các sự kiện khi rời khỏi chế độ isearch.

Một tính năng hay khác của mô-đun là khả năng thay đổi hình dạng và màu sắc con trỏ dựa trên chế độ. Ví dụ: bạn có thể sử dụng thanh dọc trong chế độ INSERT và gạch chân nhấp nháy trong chế độ TÌM KIẾM.