Có thể sử dụng hai nền màu khác nhau trong một bộ đệm vim không?

Tôi đang tìm kiếm một giải pháp khả thi cho việc áp dụng hai màu nền khác nhau trong một bộ đệm vim duy nhất tùy thuộc vào ngữ cảnh như trong ví dụ văn bản tuyệt vời này .

Một trường hợp sử dụng đó là các đoạn mã màu bên trong các tệp đánh dấu khác nhau để chúng nổi bật hơn.

Tuy nhiên tôi chưa bao giờ thấy một ví dụ với một thiết lập như vậy.

Đây có phải là tất cả có thể trong vim?

Bởi vì tôi tò mò việc này sẽ hoạt động tốt như thế nào, tôi đã hack một thứ gì đó cùng loại đó.

Như đã đề cập trong các ý kiến ​​về câu trả lời trước đó, cách duy nhất để làm điều này là lấp đầy các vùng bằng khoảng trắng; đó chính xác là những gì chúng ta làm; trước khi viết, chúng tôi xóa các khoảng trắng này, vì vậy bạn không nên làm phiền bất kỳ ai khác với nó.

Lưu ý rằng ví dụ này rất cụ thể cho kiểu đánh dấu!

Tác dụng phụ :

• Sao chép văn bản cũng sẽ sao chép rất nhiều khoảng trắng
• Sử dụng $và Endkhông còn hoạt động như mong đợi (nó đi đến cột 80) và các phím như jvà kcũng hoạt động khác nhau.
• Nền không được hiển thị khi 'list'được bật
• Các dòng trống hoàn toàn không hoạt động, bạn cần thêm thủ công một tab hoặc 4 khoảng trắng
• ... Có lẽ nhiều hơn?

Trước tiên, bạn cần thêm phần này vào ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Tất nhiên, bạn có thể điều chỉnh màu sắc theo ý thích của mình ;-)

Sau đó, thêm phần này vào vimrc của bạn:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Tôi sẽ không giải thích từng dòng mã, các ý kiến ​​sẽ làm cho ý chính chung của nó rõ ràng ;-)

Chắc chắn có thể sử dụng màu nền khác cho các yếu tố được tô sáng theo cú pháp. Chỉ cần xác định guibgvà ctermbgmàu sắc trong hilightlệnh của bạn . Cái trước đặt màu nền cho GUI Vim và cái sau cho terminal Vim.

Tuy nhiên, điều này có giới hạn quan trọng là nó chỉ có thể đặt màu nền cho các ký tự thực sự tồn tại trong tệp.

Kết quả của điều này là màu nền không thể kéo dài qua phần cuối của văn bản trên một dòng đến cạnh của cửa sổ, do đó không thể tô màu các khối mã được hiển thị trong ví dụ của bạn:

Bạn cũng có thể thay đổi màu nền của toàn bộ dòng bằng tính năng Dấu. (Xem linehltrong :help sign.txt)

Tuy nhiên, lưu ý rằng:

1. Làm như vậy đòi hỏi phải viết mã để đặt các dấu hiệu trên mỗi dòng cần được tô màu và giữ cho các cập nhật này khi nội dung của tệp thay đổi,

2. Theo mặc định, khi đặt một dấu hiệu, cột dấu hiệu sẽ được hiển thị ở bên trái của cửa sổ. Có thể thay đổi màu của cột ký hiệu với SignColumnnhóm tô sáng và trong các phiên bản gần đây hơn của Vim, nó có thể được loại bỏ hoàn toàn. (Xem :help 'signcolumn'.)

Ví dụ: để điều chỉnh giải pháp của Carpetsmoker để sử dụng cơ chế ký hiệu (mạnh mẽ hơn), bạn có thể làm như sau:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Điều này đơn giản hóa phần nào mã và có ít cảnh báo hơn phiên bản của Carpetsmoker.

Plugin DynamicSigns của @ChristianBrabandt làm cho việc sử dụng tính năng Dấu hiệu cho mục đích này dễ dàng hơn: anh mô tả cách sử dụng nó để làm như vậy trong câu trả lời này .