Chuyển đến X byte từ đây

Làm cách nào tôi có thể di chuyển X byte về phía trước, bắt đầu từ vị trí con trỏ hiện tại (bao gồm cả ngắt dòng)?

[count]gocó thể được sử dụng để di chuyển về phía trước các byte X từ đầu bộ đệm. Tôi đã thử Shift + V, G, [count]go(giả sử rằng [count]gosẽ bắt đầu đếm từ lúc bắt đầu lựa chọn của tôi), nhưng thật không may, điều đó cũng không hoạt động vì gochỉ bắt đầu đếm từ đầu bộ đệm.

Tôi cũng đã cố gắng :set rulerformat=%ohiển thị phần bù byte hiện tại (như được đề xuất bằng cách nhảy sang phần bù byte và hiển thị vị trí dưới dạng phần bù byte ), thêm các số trong đầu và cuối cùng được phát hành [count]go. Điều này hoạt động, nhưng nó không thực tế ...

Tìm kiếm này di chuyển 40 ký tự (mặc dù không phải byte) về phía trước:

/\_.\{40}/e

bằng cách tìm kiếm chính xác 40 ký tự ( \{40}) của bất kỳ loại nào, bao gồm dòng mới ( \_.) và đặt con trỏ ở cuối tìm kiếm ( /e). Xem: http://vimregex.com/#Non-Greedy , :help search-offsetvà:help \_

Ngoài ra, xem :h 23.4để chỉnh sửa nhị phân.

Cập nhật: Dựa trên câu trả lời này , đây là một hàm chuyển sang bù byte:

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

Có thể được sử dụng như thế này:

:JumpToOffset 400

hoặc gõ ánh xạ bàn phím được ánh xạ, với số đếm:

40CTRL-C

Nếu bạn không sử dụng số đếm, số đếm trước đó sẽ được sử dụng lại. Vì vậy, bạn có thể làm: 40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-Cđể nhảy 40, 40, 40, 30, 30 byte, v.v.

Nhấn Ctrl-Ođể nhảy trở lại (xem bình luận bên trong chức năng).

Tôi đã kết thúc bằng cách sử dụng giải pháp sau đây, thực hiện logic từ câu hỏi của tôi.

• [count]GOđể di chuyển [count]byte về phía trước.
• [count]Gođể di chuyển [count]byte ngược.

Thêm phần này vào .vimrc:

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

Cảm ơn VanLaser vì đã thực hiện ban đầu, điều này đưa tôi đi đúng hướng.