Đặt dấu cho giá trị trước đó của nó

Đôi khi, tôi sử dụng nhãn hiệu để điều hướng dễ dàng qua các tệp khác nhau bằng cách sử dụng mA, mB... và 'A, 'B...

Và đôi khi (thường xuyên hơn tôi muốn thừa nhận) vì sự vô tâm hoặc bất kể lý do là gì, tôi sử dụng m[LETTER]với một dấu hiệu đã tồn tại để xóa giá trị trước đó khi tôi không muốn. Hầu hết thời gian tôi làm điều đó tôi không mở tệp ban đầu được đánh dấu bằng dấu.

Trong trường hợp này khi tôi nhận ra rằng tôi đã phạm sai lầm, liệu có thể lấy giá trị trước đó của nhãn hiệu của tôi ngoài việc ghi nhớ nơi nó được trỏ đến, điều hướng đến vị trí này và đặt lại?

Tôi đã không tìm thấy một lệnh như thế trong tài liệu vì vậy nếu điều đó không tồn tại thì có một cách giải quyết thông minh mà một số bạn sử dụng trong tình huống này không?

Đây là một số VimScript cơ bản mà gần như làm những gì bạn muốn.

Chúng tôi ghi đè mathông qua mzánh xạ để lưu trữ giá trị hiện tại g:previous_markstrước khi gọi bản gốc mđể thực sự đặt dấu. Chúng tôi cũng xác định <Leader>mathông qua <Leader>mzđể hiển thị lịch sử cho dấu hiệu nói.

Bạn có thể sẽ muốn lưu trữ thông tin theo g:previous_markscách có tổ chức hơn và thêm khả năng khôi phục nhanh chóng một dấu (thay vì chỉ nhìn thấy các vị trí), nhưng ví dụ này cho thấy cách thực hiện, các điều chỉnh tiếp theo được để lại như một bài tập cho người đọc ;-)

let g:previous_marks = {}
fun! MyMark(mark)
    let l:marks = ''
    redir => l:marks
        try
            silent! execute 'marks ' . a:mark
        catch
        endtry
    redir END

    if l:marks != ''
        if !has_key(g:previous_marks, a:mark)
            let g:previous_marks[a:mark] = []
        endif
        call add(g:previous_marks[a:mark], split(l:marks, "\n")[1])
    endif

    execute 'normal! m' . a:mark
endfun

fun! ShowHistory(mark)
    if !has_key(g:previous_marks, a:mark)
        echoerr 'No history for ' . a:mark
        return
    endif

    for l:line in g:previous_marks[a:mark]
        echo l:line
    endfor
endfun

fun! MakeMappings()
    for l:char in range(97, 122)
        let l:char = nr2char(l:char)

        execute 'nnoremap <silent> m' . l:char . ' :call MyMark("' . l:char . '")<CR>'
        execute 'nnoremap <silent> <Leader>m' . l:char . ' :call ShowHistory("' . l:char . '")<CR>'
    endfor
endfun

call MakeMappings()

Không chính xác những gì bạn muốn, nhưng có lẽ hữu ích hơn: plugin chữ ký . Nó hiển thị các dấu hiện tại dưới dạng các dấu hiệu trong lề máng xối và có các phím tắt đơn giản để chỉnh sửa chúng. Nó cũng có thể đặt danh sách các dấu hiệu trong danh sách vị trí để truy cập nhanh.

Vì vấn đề thực tế dường như là điều hướng giữa nhiều tệp / vị trí, tôi đề xuất giải pháp đơn giản này, dựa trên plugin Unite :

:Unite jump -auto-preview

Lệnh này (có thể được ánh xạ tới một cái gì đó giống như <leader>jví dụ) sẽ hiển thị danh sách nhảy, với phần xem trước: mỗi lần bạn điều hướng danh sách với j/ k, một vài dòng xung quanh vị trí con trỏ trong tệp đó sẽ được hiển thị.

Thay thế:

Các dấu mặc định rất dễ bị ghi đè: có lẽ các dấu trang được đặt tên sẽ phù hợp hơn với trường hợp sử dụng của bạn, ví dụ như với plugin Simple_bookmark .