Hợp nhất các khối bằng các đường xen kẽ

Có cách nào chuyên dụng để hợp nhất hai khối văn bản bằng cách xen kẽ các dòng, giống như chuyển từ đây:

a1
a2
a3
a4
  b1
  b2
  b3
  b4

đến đó:

a1
  b1
a2
  b2
a3
  b3
a4
  b4

trong một vài lệnh?

EDIT : Tôi thực sự thích giải pháp của Sato Katsura , đây là cách tôi đã thực hiện nó:

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

Không có cách chuyên dụng để làm điều đó (theo như tôi biết), nhưng vâng, nó có thể được thực hiện với một vài lệnh:

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

Bạn có thể chạy nó với :call Interleave(5, 8, 1). Tham số đầu tiên là dòng đầu tiên để di chuyển, dòng thứ hai là dòng cuối cùng và dòng thứ ba để di chuyển chúng. Bạn có thể muốn bật số dòng để xem những gì bạn đang làm ( :set number).

Điều này giả định các khối không chồng chéo. Xem :help :movevà :help range()để hiểu làm thế nào các chức năng hoạt động.

Có lẽ có nhiều cách tốt hơn để chọn hai khối. Có một plugin nổi xung quanh được cho là để cho phép bạn trao đổi hai khối. Tôi không thể nhớ tên của plugin, nhưng tác giả (có lẽ là Tiến sĩ Chip nổi tiếng?) Đã suy nghĩ nhiều hơn về việc tìm kiếm một giao diện hơn tôi đã làm. :)

Đây là một thay thế khác:

:g/^a/+4t .
:+,+5d 

Đầu tiên sao chép các dòng có 4 dòng bên dưới vào sau dòng hiện tại ( :h :t) sau đó xóa các dòng b liên tiếp ( :h :d)

Thậm chí tốt hơn là lệnh này:

 :g/^a//^\s*b/m .

Điều đó có nghĩa là, đối với mỗi dòng bắt đầu bằng một dòng tìm tiếp theo bắt đầu bằng 'b' và di chuyển nó xuống bên dưới dòng hiện tại.

Nếu bạn muốn có một chút niềm vui với các macro và đánh dấu, bạn có thể thử một cái gì đó như thế này:

• Đầu tiên đặt một dấu ấn (ở đây a) trên dòng chứa a1vớima

• Đi đến dòng chứa b1và đánh dấu nó vớimb

• Bắt đầu ghi một macro trong thanh ghi bạn muốn (ở đây là thanh ghi q) vớiqq

• Chèn folowing trong macro của bạn: ddmb'apjma'b

• Dừng ghi macro với q

• Chơi nó nhiều lần khi cần thiết với X@qnơi Xlà số thời gian để chơi nó.

Để chi tiết macro:

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

Chỉnh sửa Như lago-lito đã đề cập đến nó trong các bình luận, phương pháp này sẽ ghi đè lên các dấu và bộ đệm.

• Đối với các nhãn hiệu tôi không nghĩ đó là một vấn đề thực sự: tôi hiếm khi sử dụng tất cả 26 điểm trong bộ đệm và tôi nghĩ rằng hầu hết mọi người sẽ tìm thấy 2 điểm miễn phí.

• Đối với bộ đệm, có thể lưu nó trong một biến tạm thời: Trước khi ghi lại việc sử dụng macro :let saveReg=getreg('"')để lưu thanh ghi và một khi hành động được thực hiện, sử dụng :call setreg('"', saveReg)để đưa thanh ghi trở về trạng thái trước đó.

Dù sao, tôi phải thừa nhận rằng giải pháp này chỉ là cách giải quyết nhanh và không tối ưu: Theo tôi , câu trả lời của Christan là tốt nhất và nên được chấp nhận vì nó không gây rối với bộ đệm và nhãn hiệu, không bắt buộc người dùng phải tạo một chức năng và cho thấy sức mạnh của lệnh toàn cầu.

Tôi vừa thấy một câu hỏi tương tự khác và giải pháp bao gồm:

Nhảy lên giữa cộng với một:

Mj

Và chạy:

:,$g/./exe 'm' 2*line('.')-line('$')-1