Liệt kê các kiểu tệp đã biết

Làm cách nào tôi có thể nhận được danh sách tên của các loại tệp mà vim hiện đang biết?

Tôi muốn có thể làm điều này để khi vim không tự động phát hiện kiểu tệp, tôi có thể thử một số kiểu tệp vim biết về điều đó có thể tương tự và xem liệu chúng có cung cấp cú pháp tô sáng hợp lý không.

Tôi biết rằng các tệp vimscript xử lý các kiểu tệp được đặt trong ftpluginthư mục theo quy ước nhưng chúng không cần phải (tôi không chắc, nhưng tôi không nghĩ các tệp vimscript trong ftpluginthư mục là đặc biệt) vì vậy tôi chỉ muốn hỏi vim những kiểu tệp mà nó biết, bất kể nó học về chúng như thế nào.

Giải pháp đơn giản

Nhập :setfiletype (với một khoảng trắng sau đó) , sau đó nhấn Ctrl-d.

Xem :help cmdline-completionđể biết thêm về tự động hoàn thành trong dòng lệnh của vim.

Giải pháp phức tạp

Giải pháp này sử dụng 'runtimepath'tùy chọn để nhận tất cả các thư mục cú pháp có sẵn, sau đó tìm nạp danh sách các tệp vimscript trong các thư mục đó với phần mở rộng của chúng bị xóa. Đây có thể không phải là cách an toàn nhất để làm điều đó, vì vậy những cải tiến được hoan nghênh:

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

Sau đó, bạn có thể sử dụng chức năng này theo bất kỳ cách nào bạn muốn, chẳng hạn như in tất cả các giá trị trong danh sách. Bạn có thể thực hiện điều đó như vậy:

for f in GetFiletypes() | echo f | endfor

Lưu ý rằng điều này có thể có thể được nén khá nhiều, nó giống như thế này để dễ đọc. Tôi sẽ không giải thích mọi chức năng và lệnh được sử dụng ở đây, nhưng đây là tất cả các trang trợ giúp cho chúng:

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

Nếu phiên bản vim của bạn đủ gần đây (v7.4.2011 +), bạn có thể yêu cầu các kiểu tệp đã biết với chức năng hiện có thể sử dụng để giúp xác định tự động hoàn thành thủ công: getcompletion()

:echo getcompletion('', 'filetype')

Nếu bạn muốn giới hạn danh sách ở dạng tệp bắt đầu bằng một 'c', bạn sẽ gọi

:echo getcompletion('c', 'filetype')

vân vân

Lưu ý: không giống như các giải pháp phân tích tên tệp và tên thư mục $VIMRUNTIME/{syntax,filetype}/, giải pháp này 'runtimepath'cũng phân tích . Theo như tôi hiểu, nó không thấy các kiểu tệp mới được xác định / đăng ký khi đang di chuyển set ft=foobar, cũng không phải sau chế độ tự động.

Bạn cũng có thể in tất cả các loại tệp trong thiết bị đầu cuối bằng cách chạy 2 lệnh sau:

1.

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2.

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

Lệnh đầu tiên chỉ đơn giản là điều hướng đến đường dẫn thời gian chạy vim của bạn (đối với tôi đó là / usr / share / vim / vim80 ).

Lệnh thứ hai liệt kê tất cả các tên loại tệp trong hai thư mục nơi vim lưu trữ các định nghĩa loại tệp.

Cập nhật

Đề xuất cải tiến cho hai lệnh của muru cung cấp:

1.

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2.

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u