ánh xạ để bao quanh biểu tượng dưới con trỏ với một biểu thức có chứa biểu tượng

Đã đọc các bài viết kịch bản vim trong một giờ, nhưng tôi sợ rằng tôi không có kỹ năng để áp dụng các bài đăng này cho vấn đề của mình. Chỉnh sửa toán học trong tài liệu latex, tôi thường muốn thay thế các ký hiệu toán học như +, -, = bằng \ Pad {+}, \ Pad {-}, \ Pad {=}, trong đó \ Pad là macro latex I ' đã xác định để đặt không gian xung quanh biểu tượng. Tôi muốn có thể đặt con trỏ của mình vào một biểu tượng như vậy, nhập một vài chữ cái, nói ;Pvà có hành động này thay thế biểu tượng bằng

\Pad{whatever the symbol under the cursor is}

Bất kỳ trợ giúp sẽ được đánh giá cao nhất!

`

function! s:PadMacro(type) abort
    if a:type ==# 'char'
        normal! `[v`]d
    elseif a:type ==# 'line'
        normal! '[V']d
    elseif a:type ==# 'v'
        normal! `<v`>d
    else
        return
    endif
    let string = '\Pad{' . @" . '}'
    silent execute "normal! i\<c-r>=string\r"
endfunction
nnoremap <silent> ;P :set operatorfunc=<sid>PadMacro<cr>g@
vnoremap <silent> ;P :<c-u>call <sid>PadMacro(visualmode())<cr>

Nếu bạn đặt mã trước đó vào vimrc của mình, nó sẽ làm những gì bạn muốn.

Để sử dụng nó, nhấn ;P{motion}và PadMacro()chức năng nên kèm theo các nhân vật được bao phủ bởi {motion}với \Pad{và }.

Ví dụ sử dụng:

• ;Plđể đặt ký tự bên dưới con trỏ (vì llà một chuyển động bao phủ ký tự dưới con trỏ)
• ;Piwđể đặt từ dưới con trỏ (vì iwlà một đối tượng văn bản bao gồm tất cả các ký tự bên trong từ bên dưới con trỏ)
• ;Pisđể đặt câu trong đó con trỏ là (vì islà một đối tượng văn bản bao gồm tất cả các ký tự bên trong câu)
• ;P$ để bao quanh các ký tự giữa con trỏ của bạn và cuối dòng
• ;P để bao quanh các nhân vật được lựa chọn trực quan

Tất cả mọi thứ được thực hiện bởi PadMacro()chức năng này được coi là một phiên bản duy nhất có nghĩa là nó có thể lặp lại.
Nói cách khác, nếu bạn có một số phần văn bản tương tự để gửi kèm theo \Pad{}thì không cần phải chạm vào ánh xạ mỗi lần, chỉ lần đầu tiên (sau đó bạn có thể nhấn .để lặp lại phiên bản cuối cùng của mình).

Để biết danh sách đầy đủ các đối tượng văn bản mà bạn có thể áp dụng bao vây của mình, hãy xem :
:help text-objects.

Ý tưởng rất đơn giản:

1. bạn cắt văn bản bạn muốn bao quanh và vào chế độ chèn,
2. bạn chèn phần đầu tiên
3. bạn chèn nội dung của thanh ghi không tên
4. bạn chèn phần cuối cùng
5. bạn thoát khỏi chế độ chèn.

Ví dụ của bạn, bạn sẽ làm:

s\Pad{<C-r>"}<Esc>

Mà có thể được ánh xạ để thuận tiện cho bạn:

" normal mode, for single characters
nnoremap ;P s\Pad{<C-r>"}<Esc>

" visual mode, for multiple characters
xnoremap ;P s\Pad{<C-r>"}<Esc>

Lưu ý rằng có thể sử dụng một thanh ghi khác nếu bạn không muốn làm lộn xộn thanh ghi không tên. Ở đây tôi sử dụng zđăng ký:

"zs\Pad{<C-r>z}<Esc>

Chỉ một giải pháp nữa cho trường hợp khi bao quanh không chỉ một biểu tượng (mẫu từ cấu hình của tôi để bao quanh với "[" & "]"

vmap Q[ O<Esc>i[<Esc>gvo<Esc>la]<Esc>
nnoremap Q[ veO<Esc>i[<Esc>gvo<Esc>la]<Esc>

Điều quan trọng là sử dụng "o" & "O" để di chuyển đến bắt đầu / kết thúc lựa chọn