Làm cách nào tôi có thể ngăn Vim viết tệp mà không bị lỗi?

Tôi đang cố gắng cải thiện mã từ câu trả lời này để yêu cầu xác nhận trước khi tạo thư mục bị thiếu, đây là những gì tôi viết:

function! CreateDirectoryAskConfirmation(path)
    if !isdirectory(a:path)
        echohl Question
        echo "Create directory " . a:path . "?"
        echohl None

        let response = nr2char(getchar())
        if response ==? "y"
            call mkdir(a:path, "p")
        endif
    endif
endfunction

autocmd BufWritePre * call CreateDirectoryAskConfirmation(expand("<afile>:p:h"))

Một điều tôi còn thiếu: khi tôi không nhấn yvào dấu nhắc tôi muốn Vim hủy bỏ việc viết để tôi không gặp lỗi E212: Can't open file for writingvà tôi không cần nhấn một phím khác để làm cho thông báo lỗi biến mất. Có cách nào để đạt được điều này?

Thay vì sử dụng BufWritePreautocmd, bạn có thể sử dụng BufWriteCmd autocmd, từ :help BufWriteCmd:

Nên viết tệp và đặt lại 'đã sửa đổi' nếu thành công, trừ khi '+' nằm trong 'cpo' và ghi vào tệp khác cpo- +.

Chúng tôi chỉ có thể gọi :writetừ autocmd. Điều này sẽ chăm sóc thiết lập modified.

Vì vậy, logic sau đó sẽ được sửa đổi để gọi :writekhi thư mục đã tồn tại và gọi :writesau khi tạo thư mục nếu nó chưa tồn tại. Nếu bạn nhấn n, chúng tôi không làm gì cả. Điều này sẽ để lại bộ đệm như hiện tại và sẽ không được đặt lại modified, do đó :qvẫn sẽ E37: No write since last changegây ra lỗi cho bạn .

function! CreateDirectoryAskConfirmation(path, dir)
    silent doautocmd BufWritePre

    " Directory exists, :write and return
    if isdirectory(a:dir)
        execute 'write ' . a:path
        silent doautocmd BufWritePost
        return
    endif

    " Ask for confirmation to create this directory
    echohl Question
    echo "Create directory `" . a:dir . "' [y/N]?"
    echohl None

    let response = nr2char(getchar())
    " mkdir() and :write if we want to make a directory
    if response ==? "y"
        call mkdir(a:dir, "p")
        execute 'write ' . a:path
        silent doautocmd BufWritePost
    endif
endfunction

autocmd BufWriteCmd * call CreateDirectoryAskConfirmation(expand("<amatch>:p"), expand("<amatch>:p:h"))