Làm cách nào tôi có thể định dạng lại chuỗi nhiều dòng trong vim khi sử dụng kiểu tệp Python?

Giả sử tôi đang chỉnh sửa một số mã Python trong vim trông giống như:

myobj.myfunc("Some string parameter that goes on and on and on and on and sometimes doesn't"
             "split very"
             "neatly over different lines so that"
             "it is formatted attractively")

Tôi muốn định dạng lại cái này để nó phản ánh đúng với cái textwidthtôi đã đặt:

myobj.myfunc("Some string parameter that goes on and on and "
             "on and on and sometimes doesn't split very "
             "neatly over different lines so that it is "
             "formatted attractively")

Có cách nào làm dễ hơn không? Nếu đây là một đoạn văn bản thông thường, gqiphoặc tương tự sẽ hữu ích, nhưng điều này sẽ không xử lý các trích dẫn được sử dụng để xóa chuỗi.

Lưu ý : Tôi đang hỏi cụ thể về Python ở đây, nhưng lý tưởng nhất, câu trả lời này sẽ phù hợp với nhiều loại ngôn ngữ lập trình cho phép tiếp tục chuỗi.

Oh đó là một khó khăn. Tôi nghĩ rằng cách tiếp cận tốt nhất có thể là một macro nhưng nhiều khả năng là một plugin. Đây là một ví dụ tôi đã đánh lên (tôi cần một sở thích tốt hơn). Nó dường như hoạt động với tôi nhưng sẽ cần plugin thụt đầu trăn để thụt lề đúng cách. Hãy thử nó.

function ReformatMultiLines()
  let brx = '^\s*"'
  let erx = '"\s*$'
  let fullrx = brx . '\(.\+\)' . erx
  let startLine = line(".")
  let endLine   = line(".")
  while getline(startLine) =~ fullrx
    let startLine -= 1
  endwhile
  if getline(endLine) =~ erx
    let endLine += 1
  endif
  while getline(endLine) =~ fullrx
    let endLine += 1
  endwhile
  if startLine != endLine
    exec endLine . ' s/' . brx . '//'
    exec startLine . ' s/' . erx . '//'
    exec startLine . ',' . endLine . ' s/' . fullrx . '/\1/'
    exec startLine . ',' . endLine . ' join'
  endif
  exec startLine
  let orig_tw = &tw
  if &tw == 0
    let &tw = &columns
    if &tw > 79
      let &tw = 79
    endif
  endif
  let &tw -= 3 " Adjust for missing quotes and space characters
  exec "normal A%-%\<Esc>gqq"
  let &tw = orig_tw
  let endLine = search("%-%$")
  exec endLine . ' s/%-%$//'
  if startLine == endLine
    return
  endif
  exec endLine
  exec 'normal I"'
  exec startLine
  exec 'normal A "'
  if endLine - startLine == 1
    return
  endif
  let startLine += 1
  while startLine != endLine
    exec startLine
    exec 'normal I"'
    exec 'normal A "'
    let startLine += 1
  endwhile
endfunction

Sau đó, bạn có thể sử dụng nó với :call ReformatMultiLines()và / hoặc sử dụng nó trong ánh xạ.

Nếu đây là một sự xuất hiện thường xuyên, tốt nhất bạn nên tìm kiếm một plugin hoặc sử dụng chức năng của @Sukima. Tuy nhiên, nếu tôi đang làm điều này một cách nhanh chóng, thì đây là những gì tôi có thể làm:

1. Thêm một dòng mới sau paren mở và trước paren đóng để các chuỗi nằm trên các dòng riêng biệt.

   myobj.myfunc(
                "Some string parameter that goes on and on and on and on and sometimes doesn't"
                "split very"
                "neatly over different lines so that"
                "it is formatted attractively"
   )
   

2. Chọn các dòng có chuỗi và xóa dấu ngoặc kép xung quanh: :norm ^x$x

3. Giảm băng thông (để tính các trích dẫn bị thiếu) :set tw-=2
4. Chọn lại và định dạng: gvgq
5. Sửa lỗi băng thông: :set tw+=2
6. Thêm lại dấu ngoặc kép : gv:norm I"<Esc>A". Thay vì <Esc>bạn muốn chèn một lối thoát theo nghĩa đen bằng cách gõ ctrl-v theo sau là phím thoát. Vì tôi ánh xạ jj để thoát, tôi thường chỉ gõ jj ở đây.
7. Tùy chọn sử dụng J để nối lại hai / hai dòng đầu tiên. Khi tôi có một chuỗi rất dài trong python như thế này, tôi thường thích bắt đầu nó trên dòng tiếp theo và chỉ thụt vào nó một cấp hơn dòng trước. Điều này mang lại nhiều không gian ngang cho chuỗi và chỉ cảm thấy tự nhiên hơn đối với tôi. Ngoài ra, bạn có thể lưu chuỗi vào một biến ở đâu đó ở trên. Giả sử đó là một chuỗi tĩnh, bạn thậm chí có thể lưu nó vào một biến toàn cục để nó ở mức thụt thấp hơn nhiều và có thể phù hợp với ít dòng hơn. Lưu ý rằng bạn phải tham gia paren đóng trên cùng một dòng, bạn có thể muốn giảm / tăng độ rộng văn bản lên 3 thay vì 2.

Phân tích cú pháp và định dạng mã là khó, đặc biệt đối với các ngôn ngữ động như Python.

Thay vì cố gắng phân tích Python trong Vimscript, tôi khuyên bạn nên sử dụng một trình định dạng bên ngoài như yapf . Với câu trả lời của tôi ở đây, bạn có thể viết nó tự động bằng cách viết với:

augroup write_cmd
    autocmd BufWritePre *.py call s:write_cmd('yapf')
augroup end

Các s:write_cmd()chức năng trong câu trả lời khác - Tôi sẽ không thêm nó ở đây vì vậy tôi sẽ không phải cập nhật nó ở hai nơi nếu tôi tìm thấy một lỗi :-)

Bạn cũng có thể thiết lập formatprgđể yapfvà tự định dạng nó với gq.

Các chức năng và ánh xạ tương ứng đã giải quyết vấn đề này cho tôi:

function! BreakMultlineString(quote)
let c = 100
while c == 100
    normal 100|
    let c = virtcol('.')
    if c == 100
        execute "normal ," . a:quote
    endif
endwhile
endfunction

function! JoinMultilineString()
    let c = "'"
    while c == "'" || c == '"'
        normal gj^
        let c = matchstr(getline('.'), '\%' . col('.') . 'c.')
        normal k
        if c == "'" || c == '"'
            normal ,j
        endif
    endwhile
endfunction

" break lines
nnoremap <Leader>" 100\|Bi"<CR>"<Esc>
nnoremap <Leader><Leader>" :call BreakMultlineString('"')<CR>
nnoremap <Leader>' 100\|Bi'<CR>'<Esc>
nnoremap <Leader><Leader>' :call BreakMultlineString("'")<CR>

" join lines
nmap <Leader>j Jds'ds"x
nnoremap <Leader>J :call JoinMultilineString()<CR>