Làm cách nào để lưu và khôi phục kết quả của lệnh 'set'?

Từ :h :setchúng tôi biết rằng

:se[t] Hiển thị tất cả các tùy chọn khác với giá trị mặc định của chúng.

Trong một vimscript tôi muốn lưu tất cả các tùy chọn đã được người dùng sửa đổi, sửa đổi chúng và sau đó khôi phục chúng về giá trị do người dùng đặt.

Làm thế nào tôi có thể làm điều đó một cách dễ dàng?

Tôi có cách đơn giản là lưu trữ kết quả của :set(hoặc một lệnh tương tự) vào một biến mà tôi có thể nguồn hoặc chuyển sang lệnh khác sau đó để khôi phục những gì nó chứa không?

Hoặc tôi phải phân tích thủ công đầu ra của lệnh (điều mà tôi có thể làm nhưng rất nhiều công việc không có gì nếu một sự thay thế đơn giản hơn tồn tại)?

1. :mkexrc

Cách dễ nhất là sử dụng :mkexrclệnh. Với lệnh này, chúng ta có thể lưu tất cả các tùy chọn đã thay đổi vào một tệp. Khi bạn cần khôi phục lại tất cả các tùy chọn đã lưu từ tệp, chỉ cần :sourcenó.

mkexrc snapshot
source snapshot

2. :setvà:redir

Các :mkexrclệnh thiết sử dụng một tập tin để giữ tất cả các tùy chọn. (Và nó cũng tiết kiệm ánh xạ chính hiện hành.) Khi chúng ta không muốn sử dụng bất kỳ tập tin, chúng ta có thể chuyển hướng đầu ra của :setlệnh vào biến vim với :redir.

redir => snapshot
silent set
redir END

Sau đó, chúng tôi có thể khôi phục lại tất cả các tùy chọn từ ảnh chụp nhanh như sau.

for opt in split(snapshot,'\n')[1:]
    exe "silent set " . opt
endfor

Cách tiếp cận trên là nhanh chóng và dễ sử dụng. Nhưng cách tiếp cận có hai vấn đề. Đầu tiên, chúng ta phải thoát một số ký tự bao gồm khoảng trắng từ ảnh chụp nhanh ( :help option-backslash) . Nếu không, chúng ta có thể gặp lỗi khi các ký tự này không được thoát. Ví dụ,

set breakat=@ !+=

làm tăng lỗi 'E518' nhưng,

set breakat=@\ \!+=

hoạt động tốt

Và vấn đề thứ hai là tất cả các phím đặc biệt được thay đổi thành các ký tự bình thường khi chúng ta chuyển hướng đầu ra thành ảnh chụp nhanh. Ví dụ: ^I(tab) được thay đổi theo nghĩa đen thành ^và I. Cách giải quyết có thể phức tạp một chút.

let g:optionDict = {}

function SaveOpts()
    redir => snapshot
    " We make a snapshot of options which differ from their default value.
    " If we want to make a snapshot of all options, do set all.
    silent set
    redir END

    for opt in split(snapshot, '\W\+')
        if strlen(opt) > 3
            if exists('&' . opt)
                exe 'let g:optionDict.'. opt . '=&' . opt
            elseif opt[0:1] == 'no' && exists('&' . opt[2:])
                exe 'let g:optionDict.'. opt[2:]. '=&' . opt[2:]
            endif
        endif
    endfor
endfunc

function RestoreOpts()
    for [opt, val] in items(g:optionDict)
        try
            exe 'silent set ' . opt . '=' . escape(val, " \t|\\\"")
        catch /:E474/ " Invalid argument, do set {option} or no{option}
            if val == '1'
                exe 'silent set ' . opt
            elseif val == '0'
                exe 'silent set no' . opt
            endif
        endtry
    endfor
endfunc

3. :setlocal

Chúng tôi cũng có thể lưu một tùy chọn khôi phục bằng tay với :setlocal.

:setlocalchỉ ảnh hưởng đến bộ đệm hoặc cửa sổ hiện tại. Nếu chúng tôi thay đổi tùy chọn với :setlocal, :setlocal {option}<hoặc :set {option}<có thể khôi phục lại các tùy chọn đã thay đổi. Cái trước đặt giá trị cục bộ của {tùy chọn} từ giá trị toàn cục của nó và cái sau loại bỏ tất cả các tùy chọn cục bộ để tất cả các giá trị tùy chọn trở về giá trị toàn cầu của chúng. Ví dụ,

setlocal ts=16
set ts<

Bạn có thể truy cập giá trị của cài đặt bằng let option_val = &optiontập lệnh. Những gì tôi đã thấy là sử dụng một lệnh để lưu trữ các tùy chọn mà bạn muốn thay đổi. Bạn lặp lại qua lệnh để lưu giá trị cũ và đặt giá trị mới.

Thí dụ

Đây là một cách tiếp cận trực tiếp hơn. Tôi sẽ sử dụng điều này nếu các cài đặt được biết trước.

function! s:do_something() abort
  " Options needed by the plugin
  let plugin_options = {
        \ 'list': 0,
        \ 'winfixwidth': 1,
        \ 'autoindent': 0,
        \ 'filetype': 'ini',
        \ }

  echo 'desired:' plugin_options

  for option in keys(plugin_options)
    execute 'let old_val = &'.option
    execute 'let &'.option.' = plugin_options[option]'
    let plugin_options[option] = old_val
  endfor

  echo 'changed:' plugin_options

  for option in keys(plugin_options)
    execute 'let &'.option.' = plugin_options[option]'
  endfor
endfunction


call s:do_something()

Các plugin_optionsbiến được scoped đến chức năng, vì vậy nó có thể được tái sử dụng để lưu trữ các giá trị tùy chọn cũ.

Ví dụ nâng cao

Tập lệnh bên dưới sẽ cho phép bạn thay đổi cài đặt ở bất kỳ đâu trong tập lệnh của mình trong khi duy trì cài đặt gốc cho đến khi bạn gọi s:restore_settings()

function! s:set(option, value) abort
  if !exists('b:_saved_settings')
    let b:_saved_settings = {}
  endif

  " Only save the original values
  if !has_key(b:_saved_settings, a:option)
    execute 'let b:_saved_settings[a:option] = &'.a:option
  endif

  execute 'let &'.a:option.' = a:value'
endfunction

function! s:restore_settings(...) abort
  if !exists('b:_saved_settings')
    return
  endif

  if a:0
    for option in a:000
      if has_key(b:_saved_settings, option)
        execute 'let &'.option.' = b:_saved_settings[option]'
        call remove(b:_saved_settings, option)
      endif
    endfor
  else
    for option in keys(b:_saved_settings)
      execute 'let &'.option.' = b:_saved_settings[option]'
    endfor

    unlet! b:_saved_settings
  endif
endfunction


" Options needed by the plugin
call s:set('list', 0)
call s:set('winfixwidth', 1)
call s:set('autoindent', 0)
call s:set('filetype', 'ini')

echo 'original:' b:_saved_settings
call s:restore_settings('list', 'filetype')
echo 'partial restore:' b:_saved_settings

call s:restore_settings()

s:set()có phần giống với set. Nó sẽ lưu giá trị của cài đặt ban đầu nếu nó chưa được lưu, sau đó sử dụng giá trị cài đặt của bạn.

Gọi s:restore_settings()mà không có đối số sẽ thực hiện khôi phục đầy đủ các thay đổi của bạn. Với các đối số, nó sẽ khôi phục một phần chúng. Nếu bạn quyết định sử dụng điều này, sẽ đáng để gọi s:restore_settings()trước khi gọi ban đầu s:set()trong trường hợp tập lệnh của bạn trước đó gặp lỗi trước khi khôi phục.

Trong lh-vim-lib , tôi cung cấp một lh#on#exit()hàm cho phép khôi phục những thứ khác nhau về giá trị trước đó của chúng.

Về các lựa chọn, về bản chất, nó chỉ đăng ký (để sau) a exe 'let &opt='.&opt. Tôi sử dụng nó theo cách này:

let cleanup = lh#on#exit()
      \.restore('&efm')
try
   ... change &efm here ...
   do stuff that may fail
finally
   call cleanup.finalize()
endtry

Chúng tôi có thể đăng ký nhiều phục hồi như chúng tôi muốn. Ví dụ, chúng ta có thể nhắm mục tiêu một tùy chọn bộ đệm cục bộ : l:&efm. Tuy nhiên tôi không biết cách nào để nói: "quay trở lại giá trị tùy chọn toàn cầu".

Lưu ý rằng finallymệnh đề này rất quan trọng. Nếu bất kỳ thao tác nào có thể thất bại, nếu không có nó, tùy chọn sẽ không được khôi phục về cài đặt của người dùng cuối.

Tôi chưa cung cấp cách khôi phục bất kỳ tùy chọn nào có thể - xem câu trả lời của @ MS.Kim để xem làm thế nào chúng ta có thể có được danh sách của họ. Hoặc chúng ta có thể nghe tùy chọn thay đổi sự kiện hoặc chơi với c_CTRL-A_HOMEthủ thuật cũ (1). Nhưng, thành thật mà nói, tôi thực sự không nhìn thấy điểm. Khi, cục bộ (trong một hàm), tôi thay đổi giá trị tùy chọn, tôi biết chính xác tùy chọn nào tôi sẽ điều chỉnh.

Lưu ý rằng tôi cũng có thể:

• khôi phục các tùy chọn plugin (biến) có thể là toàn cục hoặc bộ đệm cục bộ -> .restore_option(varname)
• đăng ký hành động -> .register(':q')
• khôi phục ánh xạ cục bộ bộ đệm (hoặc xác định chúng) -> .restore_buffer_mapping('<c-y>', 'i')

(1) Tôi đã tính đến lh-vim-lib (như thường lệ) -> echo lh#command#matching_askvim('option', '')

" Function: lh#command#matching_askvim(what, lead) {{{3
function! lh#command#matching_askvim(what, lead) abort
  let cleanup = lh#on#exit()
        \.register('delcom LHAskVimMatchingCompletion')
  try
    exe 'command! -complete='.a:what.' -nargs=* LHAskVimMatchingCompletion :echo "<args>"'
    silent! exe "norm! :LHAskVimMatchingCompletion ".a:lead."\<c-a>\"\<home>let\ cmds=\"\<cr>"
    return split(cmds, ' ')[1:]
  finally
    call cleanup.finalize()
  endtry
endfunction