Trong Bảng tính Google, không sử dụng Tập lệnh ứng dụng, v.v., có thể đạt được những điều sau với một công thức duy nhất, chẳng hạn như arrayformula(hoặc có thể mmulthoặc một cái gì đó lạ, nhưng không điền vào) ở đầu Cột B?:

kịch bản:

Cột A: các ô trống hoặc không trống

mục tiêu:

Cột B: chứa ô không trống cuối cùng của cột A

thí dụ:

input | output
===============
    a | a
------+--------
      | a
------+--------
      | a
------+--------
    5 | 5
------+--------
      | 5
------+--------
    c | c
------+--------
    c | c
------+--------
      | c
------+--------
    a | a
------+--------

Câu trả lời ngắn

=ArrayFormula(vlookup(ROW(1:10),{IF(LEN(A1:A10)>0,ROW(1:10),""),A1:A10},2))

Giải trình

Giả sử dữ liệu đầu vào trong Column Abảng dưới đây và công thức trên nằm trong ô B1.

Lưu ý: Để giúp đánh giá công thức dễ dàng hơn, Column A(đầu vào) không lặp lại các giá trị nhưng nó sẽ hoạt động với bất kỳ loại giá trị nào (chữ, số, ký hiệu, lặp lại, chưa sắp xếp, v.v.)

      |    A       B   
  === + ======= =======
   1  |    a       a   
   2  |            a   
   3  |    b       b   
   4  |            b   
   5  |            b   
   6  |    c       c   
   7  |    d       d   
   8  |    e       e   
   9  |            e   
  10  |    f       f   

VLOOKUP đã được chọn vì nó có thể được sử dụng để tìm các giá trị gần đúng và nó có thể trả về nhiều giá trị (mảng).

Vì các giá trị đầu vào có thể xuất hiện theo bất kỳ thứ tự nào, thay vì sử dụng các giá trị thực tế, số hàng được sử dụng cho các ô không trống và các ô trống đã gán một chuỗi trống "".

Nó được sử dụng LENthay ISBLANKvì bởi vì các ô có công thức trả về chuỗi trả về chuỗi rỗng FALSEvà điều này có thể gây ra sự cố trong một số trường hợp phổ biến.

IF(LEN(A1:A10)>0,ROW(1:10),"")

LƯU Ý: Trong trường hợp bạn muốn lưu ba ký tự, tham số thứ hai ( ""ký tự là dấu tách tham số ,) có thể bị xóa. Khi phân tích phần này của công thức, các ô trống sẽ trở lại FALSE.

Khi VLOOKUPyêu cầu cột tra cứu là cột đầu tiên, thay vì một phạm vi, một mảng được thực hiện "bán thủ công" đã được sử dụng.

{IF(LEN(A1:A10)>0,ROW(1:10),""),A1:A10}

Cách tiếp cận trên giúp chúng tôi tiết kiệm tế bào và thời gian xử lý.

Ngoài bài đăng trước, công thức dưới đây sẽ cho phép sử dụng phạm vi kết thúc mở để đầu ra sẽ 'tự động mở rộng' khi các giá trị mới được thêm vào cột được tham chiếu (A trong ví dụ bên dưới).

=ArrayFormula(
   if(row(A2:A) <= max(if(not(isblank(A2:A)),row(A2:A))),
      vlookup(row(A2:A),filter({row(A2:A),A2:A},len(A2:A)),2),
   )
 )

EDIT: nếu bạn không muốn đầu ra bị giới hạn ở hàng cuối cùng của sourcedata, bạn có thể 'mã hóa cứng' hàng cuối như thế này:

=ArrayFormula( if(row(A:A) <= 20, vlookup(row(A:A),filter({row(A:A),A:A},len(A:A)),2), ) )

Bạn có thể thử công thức này:

=ArrayFormula(if(ISBLANK(A1:A10);INDEX(A1:A10;ROW()-1;COLUMN());A1:A10))