Định vị biểu tượng máy tính để bàn ở bên trái thay vì bên phải

Bất kỳ cách nào để tự động tạo bí danh hoặc biểu tượng để hiển thị ở bên trái màn hình apple. Theo mặc định, họ đi bên phải.

Không có cách nào để buộc các biểu tượng tự động chuyển sang bên trái (và được sắp xếp theo tiêu chí bạn chọn).

Như một giải pháp thay thế, bạn có thể thay đổi Tùy chọn xem trong Finder để không sắp xếp các mục theo bất kỳ tiêu chí và đặt biểu tượng thủ công ở bên trái.

• Bấm vào một khoảng trống trên màn hình nền.
• Nhấn Cmd+ Jhoặc sử dụng chuột để vào menu Tìm kiếm > Hiển thị tùy chọn xem .
• Trong danh sách Sắp xếp theo: thả xuống trong hộp thoại, chọn Không hoặc Snap to Grid .
• Bạn sẽ có thể thả các tập tin bất cứ nơi nào trên máy tính để bàn của bạn và họ sẽ ở lại đó.

Xem Mac Basics: Sửa đổi cửa sổ của bạn để biết thêm thông tin.

Đồng thời đi qua các trang Cơ bản về Mac để tìm hiểu thêm về cách sử dụng máy Mac.

Đây không phải là giải pháp tốt nhất nhưng nó có thể hoạt động nếu không có gì khác ...

1. Tạo một hành động thư mục tự động liên kết với máy tính để bàn.
2. Thêm mục: "chạy applescript"

3. Dán đoạn mã sau vào hộp văn bản applescript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Vì vậy, bất cứ khi nào một tệp được thêm vào Bàn làm việc của bạn, tất cả các tệp sẽ được sắp xếp lại theo thứ tự bảng chữ cái ...

Sắp xếp tất cả các thư mục theo thứ tự bạn muốn chúng. Sau đó, trong mục Xem nhấn 'dọn dẹp.' Điều này sẽ sắp xếp mọi thứ độc đáo. Sau đó, bạn có thể chỉ cần làm nổi bật tất cả các thư mục và định vị chúng chính xác nơi bạn muốn chúng. Máy Mac không tổ chức các thư mục ở bên trái, chỉ bên phải, nhưng với một vài bước dễ dàng, bạn có thể sắp xếp mọi thứ gọn gàng ở bên trái.

Tôi chỉ tô sáng tất cả các thư mục từ phía bên tay phải, sau đó lấy tất cả chúng và dán sang bên trái.