Tôi chủ yếu sử dụng chức năng này:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
Bạn cũng có thể gán một phím tắt cho một tập lệnh như các tập lệnh bên dưới.
Sử dụng lại tab hiện có hoặc tạo cửa sổ mới (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Sử dụng lại một tab hiện có hoặc tạo một tab mới (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Luôn tạo một tab mới (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
Hai tập lệnh đầu tiên có một vài lợi thế so với các dịch vụ được thêm vào trong 10.7:
- Kể từ ngày 10.9, có một lỗi trong đó các dịch vụ nhận thư mục làm đầu vào không bao giờ được liệt kê trong menu dịch vụ trong chế độ xem cột. Nếu bạn chỉ định Tab thiết bị đầu cuối mới tại dịch vụ thư mục một phím tắt, nó sẽ không hoạt động trong chế độ xem cột.
- Họ sử dụng thư mục trên thanh tiêu đề thay vì yêu cầu bạn chọn thư mục trước.
- Họ sử dụng lại tab trên cùng nếu nó không bận, ví dụ: chạy lệnh, hiển thị trang man hoặc chạy emacs.
Nếu bạn sử dụng 10.7 hoặc 10.8, hãy đổi tell application "Finder" to set p to POSIX path of (insertion location as alias)thành:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
Có lỗi trong 10.7 và 10.8 (nhưng không phải trong 10.9 hoặc 10.6) khi Finder bỏ qua các cửa sổ được tạo sau lần lấy nét cuối cùng được chuyển sang ứng dụng khác và quay lại khi lấy thuộc insertion locationtính.
