Hiển thị / Ẩn tập tin ẩn mà không khởi động lại công cụ tìm?

Tôi đã hiểu rằng sau đây là cách để thay đổi mức độ hiển thị của các tệp ẩn:

defaults write com.apple.finder AppleShowAllFiles YES
# replace YES with NO to hide hidden files
killall -HUP Finder /System/Library/CoreServices/Finder.app

Có cách nào để hiển thị / ẩn các tập tin ẩn mà không giết Finder?

Chỉnh sửa: Điều này không còn xuất hiện để làm việc kể từ El Capitan. killall Finderdường như là cách duy nhất bây giờ

Đây là phương pháp El Capitan hiện tại của tôi, cũng nên hoạt động cho Mountain Lion & cũ hơn

set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState & "; killall Finder"

Dành cho Mavericks & Yosemite

Bạn không cần phải khởi động lại Finder, chỉ làm mới các cửa sổ.

Bản sao này sẽ chuyển trạng thái & làm mới ...

set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState


tell application "Finder"
    set theWindows to every Finder window
    repeat with i from 1 to number of items in theWindows
        set this_item to item i of theWindows
        set theView to current view of this_item
        if theView is list view then
            set current view of this_item to icon view
        else
            set current view of this_item to list view

        end if
        set current view of this_item to theView
    end repeat
end tell

Tín dụng cho ganbustein cho thói quen ẩn / hiển thị được cải thiện

Trên macOS Sierra, phiên bản 10.12.4 trở lên, bạn có thể nhấn ⌘+ Shift+ . ₍ dấu chấm ₎ , để chuyển các tệp ẩn bên trong Finder.

Chỉnh sửa muộn: Điều này hiện đang hoạt động trên Mojave, kể từ b5, ngày 18 tháng 8 năm 2018.