Tại sao tiếng ồn Perlin của tôi lại trông giống như một khối của người Do Thái?

Tôi đã cố gắng tự mình thực hiện tiếng ồn Perlin bằng cách sử dụng lý thuyết (theo flafla2.github.io/2014/08/09/perlinnoise.html). Thật không may, tôi không thể đạt được giao diện của tiếng ồn Perlin "nguyên bản".

Lý do nào khiến đoạn mã dưới đây biểu hiện một phiên bản khối của Perlin Noise?

Tôi nên cải thiện / thay đổi mã gì để nó tạo ra tiếng ồn Perlin mà không có các tạo tác?

Tôi nghi ngờ có thể có vấn đề trong cách tôi nội suy hoặc trong gradsvectơ. Các gradsvector chứa các sản phẩm chấm của (vector ngẫu nhiên cho điểm lưới) và (vector kích thước) - cho tất cả 4 điểm lân cận mạng. (Các vectơ ngẫu nhiên và kích thước được mô tả trong liên kết đầu tiên.)

Hộp cát GLSL: http://glslsandbox.com/e#32663.0

float fade(float t) { return t * t * t * (t * (t * 6. - 15.) + 10.); }
vec2 smooth(vec2 x) { return vec2(fade(x.x), fade(x.y)); }

vec2 hash(vec2 co) {
    return fract (vec2(.5654654, -.65465) * dot (vec2(.654, 57.4), co));
}

float perlinNoise(vec2 uv) {
    vec2 PT  = floor(uv);
    vec2 pt  = fract(uv);
    vec2 mmpt= smooth(pt);

    vec4 grads = vec4(
        dot(hash(PT + vec2(.0, 1.)), pt-vec2(.0, 1.)),   dot(hash(PT + vec2(1., 1.)), pt-vec2(1., 1.)),
        dot(hash(PT + vec2(.0, .0)), pt-vec2(.0, .0)),   dot(hash(PT + vec2(1., .0)), pt-vec2(1., 0.))
    );

    return 5.*mix (mix (grads.z, grads.w, mmpt.x), mix (grads.x, grads.y, mmpt.x), mmpt.y);
}

float fbm(vec2 uv) {
    float finalNoise = 0.;
    finalNoise += .50000*perlinNoise(2.*uv);
    finalNoise += .25000*perlinNoise(4.*uv);
    finalNoise += .12500*perlinNoise(8.*uv);
    finalNoise += .06250*perlinNoise(16.*uv);
    finalNoise += .03125*perlinNoise(32.*uv);

    return finalNoise;
}

void main() {
    vec2 position = gl_FragCoord.xy / resolution.y;
    gl_FragColor = vec4( vec3( fbm(3.*position) ), 1.0 );
}

Nội suy có vẻ tốt. Vấn đề chính ở đây là hàm băm bạn đang sử dụng không tốt lắm. Nếu tôi chỉ nhìn vào một quãng tám và hình dung ra kết quả băm bằng cách xuất ra hash(PT).x, tôi nhận được một cái gì đó như thế này:

Điều này được cho là hoàn toàn ngẫu nhiên trên mỗi ô vuông, nhưng bạn có thể thấy rằng nó có rất nhiều mẫu đường chéo trong đó (nó trông giống như một bàn cờ), vì vậy nó không phải là một hàm băm rất ngẫu nhiên và các mẫu đó sẽ xuất hiện trong tiếng ồn do nó tạo ra.

Vấn đề khác là hàm băm của bạn chỉ trả về các vectơ độ dốc trong [0, 1], trong khi chúng phải ở [−1, 1] để có được độ dốc theo mọi hướng. Đó là phần dễ dàng để sửa chữa bằng cách ánh xạ lại.

Để khắc phục những vấn đề đó, tôi đã chuyển mã sang sử dụng hàm băm này (mà tôi đã học được từ Mikkel Gjoel và có lẽ là do một bài báo của WJJ Rey ):

vec2 hash(vec2 co) {
    float m = dot(co, vec2(12.9898, 78.233));
    return fract(vec2(sin(m),cos(m))* 43758.5453) * 2. - 1.;
}

Lưu ý rằng do các chức năng trig, nó sẽ đắt hơn một chút so với phiên bản của bạn. Tuy nhiên, nó cải thiện đáng kể sự xuất hiện của tiếng ồn kết quả: