Làm cách nào để vào chế độ chỉ xem khi duyệt mã nguồn Emacs từ trợ giúp?

Khi tôi duyệt trợ giúp Emacs cho các chức năng thông qua C-h f, tôi thường muốn xem qua triển khai Elisp / C. Tôi muốn nhập view-modetự động khi tôi truy cập mã nguồn theo cách này để tránh sửa đổi không cần thiết. Có một cái móc hoặc chức năng tôi có thể khuyên để thực hiện điều này?

Cập nhật (sau một đêm ngủ): Câu trả lời này có một lỗ hổng lớn: nó cho phép view-modekhi điều hướng đến bất kỳ chức năng nào , không chỉ các nguồn Emacs. Điều này có thể được khắc phục, nhưng tốt hơn hết là bạn nên sử dụng câu trả lời của @phils .

Bằng cách thực hiện C-h f describe-function RETvà sau đó đọc mã nguồn của describe-functiontôi phát hiện ra rằng nó tạo ra một "nút" thuộc loại đặc biệt để liên kết đến các định nghĩa hàm : help-function-def.

Chạy zrgrepvới chuỗi này (" help-function-def") chỉ cho tôi help-mode.el.gz.

Sau khi đào tất cả, chúng ta có thể thay thế loại nút này bằng chính nút của mình (lưu ý nhận xét trong mã):

(define-button-type 'help-function-def
  :supertype 'help-xref
  'help-function (lambda (fun file)
               (require 'find-func)
               (when (eq file 'C-source)
                 (setq file
                       (help-C-file-name (indirect-function fun) 'fun)))
               ;; Don't use find-function-noselect because it follows
               ;; aliases (which fails for built-in functions).
               (let ((location
                      (find-function-search-for-symbol fun nil file)))
                 (pop-to-buffer (car location))
                 (if (cdr location)
                     (goto-char (cdr location))
                   (message "Unable to find location in file")))
                   (view-mode t)) ; <= new line: enable view-mode
  'help-echo (purecopy "mouse-2, RET: find function's definition"))

Theo như tôi có thể nói không có chức năng để thêm lời khuyên: Emacs sử dụng một lambdaở đây. Mặt khác (như được chỉ ra bởi @rationalrevolt ) người ta có thể thay thế thuộc help-functiontính của help-function-defloại nút:

(require 'help-mode)
(let ((help-func (button-type-get 'help-function-def 'help-function)))
  (button-type-put 'help-function-def 'help-function
                   `(lambda (func file)
                      (funcall ,help-func func file) (view-mode t))))

Bạn có thể sử dụng các biến thư mục-cục bộ để làm cho các tệp nguồn của Emacs chỉ đọc theo mặc định. (Xem thêm C-hig (emacs) Directory Variables RET).

Tạo một tệp được gọi .dir-locals.elở thư mục gốc của cây thư mục mà bạn muốn bảo vệ, với các nội dung sau:

((nil . ((eval . (view-mode 1)))))

Chỉnh sửa: Michał Politowski chỉ ra trong các nhận xét cho phép view-modetheo cách này là có vấn đề, bởi vì khi bạn loại bỏ bộ đệm với qnó cũng sẽ vô hiệu hóa chế độ, có nghĩa là lần sau bạn truy cập bộ đệm đó view-modesẽ không được bật.

Chỉnh sửa 2: Constantine đã cung cấp một giải pháp cho vấn đề đó trong các bình luận bên dưới:

((nil . ((eval . (when buffer-file-name (view-mode-enter nil #'kill-buffer))))))

Điều này hữu ích thêm một bài kiểm tra để đảm bảo rằng bộ đệm đã truy cập một tệp, nhưng thay đổi chính là việc sử dụng view-mode-enterthay vì view-mode, vì trước đây có một EXIT-ACTIONđối số xác định những việc cần làm khi qđược nhập. Trong trường hợp này, hành động thoát là để giết bộ đệm, đảm bảo rằng lần tiếp theo tệp được truy cập, nó sẽ lại kết thúc view-mode.

Chỉnh sửa 3: Theo đường dẫn đó, chúng ta cũng có thể thấy rằng EXIT-ACTIONcuối cùng được chỉ định được truyền cho view-mode-exithàm và chuỗi doc của nó cung cấp cho chúng ta một giải pháp thay thế:

view-no-disable-on-exit is a variable defined in `view.el'.
Its value is nil

Documentation:
If non-nil, View mode "exit" commands don't actually disable View mode.
Instead, these commands just switch buffers or windows.
This is set in certain buffers by specialized features such as help commands
that use View mode automatically.

Do đó chúng ta có thể sử dụng như sau:

((nil . ((eval . (when buffer-file-name
                   (setq-local view-no-disable-on-exit t)
                   (view-mode-enter))))))

Tôi sử dụng phương pháp thay thế mà bạn có thể chỉ định hoàn toàn trong tệp init của mình (trái ngược với việc tạo .dir-locals.eltệp) và tôi chỉ đơn giản làm cho các tệp chỉ đọc thay vì sử dụng view-mode. Cấu hình của tôi trông như thế này:

;; Emacs
(dir-locals-set-class-variables
 'emacs
 '((nil . ((buffer-read-only . t)
           (show-trailing-whitespace . nil)
           (tab-width . 8)
           (eval . (whitespace-mode -1))))))

(dir-locals-set-directory-class "/usr/local/src/emacs" 'emacs)
(dir-locals-set-directory-class "/usr/local/share/emacs" 'emacs)
(dir-locals-set-directory-class "/usr/share/emacs" 'emacs)

Rõ ràng bạn có thể làm điều tương tự cho thư mục elpa của mình và bất kỳ thư mục nào khác chứa mã nguồn của bên thứ ba.

Tôi nghĩ rằng tất cả những gì bạn cần là thêm một cái móc :

(add-hook 'find-function-after-hook 'view-mode)

Điều này không giải quyết trường hợp cụ thể của bạn, nhưng trường hợp chung hơn là chuyển sang view-modebất cứ khi nào bạn truy cập tệp nguồn từ bộ đệm trợ giúp. Tôi đang cung cấp nó như là một thay thế cho câu trả lời của @ Constantine, vì nó không thể đọc được như một bình luận.

Tôi có vẻ như ban đầu tôi đã nhận được điều này từ EmacsWiki .

(defadvice find-function-search-for-symbol (after view-function-source last (symbol type library) activate)
  "When visiting function source via Help, switch to view-mode"
  (with-current-buffer (car ad-return-value)
    (view-mode 1)))

(defadvice find-variable-noselect (after view-var-source last (variable &optional file) activate)
  "When visiting variable source via Help, switch to view-mode"
  (with-current-buffer (car ad-return-value)
    (view-mode 1)))

Đây là một giải pháp hoạt động cho tài liệu tích hợp và một ví dụ cho thấy cách mở rộng nó sang ELPA. Nó hoạt động bằng cách khớp đường dẫn đến tệp hiện tại với một số biểu thức chính quy và áp dụng read-only-modenếu bất kỳ trong số chúng khớp.

Lưu ý rằng bộ đệm là chỉ đọc nếu bạn truy cập nó thông qua dired, không chỉ thông qua trợ giúp.

Tôi đã thêm một hook chạy sau khi vào emacs-lisp-modekiểm tra xem đường dẫn đến tệp có khớp /\.el\.gz$/hay không và áp dụng chế độ chỉ đọc nếu có.

(defun readonly-if-el-gz ()
  (cond
   ((string-match "\\.el\\.gz\\'" (or (buffer-file-name) ""))
    (read-only-mode +1))))

(add-hook 'emacs-lisp-mode-hook 'readonly-if-el-gz)

Đây là một ví dụ kiểm tra ELPA, bằng cách sử dụng heuristic rằng bất kỳ đường dẫn nào chứa .emacs.d/elpathực sự là mã ELPA.

(defun readonly-if-internal ()
  (let
      ((name (or (buffer-file-name) "")))
    (cond
     ((string-match "\\.el\\.gz\\'" name) (read-only-mode +1))
     ((string-match "\\.emacs\\.d/elpa" name) (read-only-mode +1)))))

(add-hook 'emacs-lisp-mode-hook 'readonly-if-internal)