Một phương thức nhanh hơn để có được `line-number-at-pos` trong các bộ đệm lớn

Hàm line-number-at-pos(khi lặp lại khoảng 50 lần) đang gây ra sự chậm chạp đáng chú ý trong các bộ đệm bán lớn - ví dụ: 50.000 dòng - khi điểm gần cuối bộ đệm. Làm chậm lại, ý tôi là tổng cộng khoảng 1,35 giây.

Thay vì sử dụng elispfunciton 100% để đếm các dòng và goto trên cùng của bộ đệm, tôi quan tâm đến một phương pháp kết hợp khai thác các khả năng C tích hợp chịu trách nhiệm cho số dòng xuất hiện trên dòng chế độ. Số dòng xuất hiện trên dòng chế độ xảy ra ở tốc độ ánh sáng, bất kể kích thước của bộ đệm.

Đây là một chức năng kiểm tra:

(defmacro measure-time (&rest body)
"Measure the time it takes to evaluate BODY.
http://lists.gnu.org/archive/html/help-gnu-emacs/2008-06/msg00087.html"
  `(let ((time (current-time)))
     ,@body
     (message "%.06f" (float-time (time-since time)))))

(measure-time
  (let* (
      line-numbers
      (window-start (window-start))
      (window-end (window-end)))
    (save-excursion
      (goto-char window-end)
      (while
        (re-search-backward "\n" window-start t)
        (push (line-number-at-pos) line-numbers)))
    line-numbers))

Thử

(string-to-number (format-mode-line "%l"))

Bạn có thể trích xuất thông tin khác bằng cách sử dụng % -Xây dựng được mô tả trong Hướng dẫn Lisp của Emacs.

Hãy cẩn thận:

Ngoài những hạn chế được chỉ ra bởi wasamasa và Stefan (xem bình luận bên dưới), điều này không hoạt động đối với các bộ đệm không được hiển thị.

Thử đi:

(with-temp-buffer
  (dotimes (i 10000)
    (insert (format "%d\n" i)))
  (string-to-number (format-mode-line "%l")))

và so sánh với

(with-temp-buffer
  (dotimes (i 10000)
    (insert (format "%d\n" i)))
  (line-number-at-pos))

nlinum.el sử dụng như sau:

(defvar nlinum--line-number-cache nil)
(make-variable-buffer-local 'nlinum--line-number-cache)

;; We could try and avoid flushing the cache at every change, e.g. with:
;;   (defun nlinum--before-change (start _end)
;;     (if (and nlinum--line-number-cache
;;              (< start (car nlinum--line-number-cache)))
;;         (save-excursion (goto-char start) (nlinum--line-number-at-pos))))
;; But it's far from clear that it's worth the trouble.  The current simplistic
;; approach seems to be good enough in practice.

(defun nlinum--after-change (&rest _args)
  (setq nlinum--line-number-cache nil))

(defun nlinum--line-number-at-pos ()
  "Like `line-number-at-pos' but sped up with a cache."
  ;; (assert (bolp))
  (let ((pos
         (if (and nlinum--line-number-cache
                  (> (- (point) (point-min))
                     (abs (- (point) (car nlinum--line-number-cache)))))
             (funcall (if (> (point) (car nlinum--line-number-cache))
                          #'+ #'-)
                      (cdr nlinum--line-number-cache)
                      (count-lines (point) (car nlinum--line-number-cache)))
           (line-number-at-pos))))
    ;;(assert (= pos (line-number-at-pos)))
    (setq nlinum--line-number-cache (cons (point) pos))
    pos))

với cấu hình bổ sung sau trong chức năng chế độ:

(add-hook 'after-change-functions #'nlinum--after-change nil t)