Bạn đã thêm một nút cho bạn DataGridViewvà bạn muốn chạy một số mã khi nhấp vào.
Dễ dàng dễ dàng - chỉ cần làm theo các bước sau:
Không:
Đầu tiên, đây là những gì KHÔNG nên làm:
Tôi sẽ tránh các đề xuất trong một số câu trả lời khác ở đây và thậm chí được cung cấp bởi tài liệu tại MSDN để mã hóa chỉ mục cột hoặc tên cột để xác định xem có nhấp vào nút không. Sự kiện nhấp đăng ký cho toàn bộ lưới, vì vậy bằng cách nào đó bạn cần xác định rằng một nút đã được nhấp, nhưng bạn không nên làm như vậy bằng cách giả sử rằng nút của bạn nằm trong một tên hoặc chỉ mục cột cụ thể ... có một cách dễ dàng hơn ...
Ngoài ra, hãy cẩn thận những sự kiện bạn muốn xử lý. Một lần nữa, các tài liệu và nhiều ví dụ nhận được điều này sai. Hầu hết các ví dụ xử lý CellClicksự kiện sẽ kích hoạt:
khi bất kỳ phần nào của một ô được bấm.
... nhưng cũng sẽ kích hoạt bất cứ khi nào tiêu đề hàng được nhấp. Điều này đòi hỏi phải thêm mã bổ sung đơn giản để xác định xem e.RowIndexgiá trị nhỏ hơn 0
Thay vào đó xử lý những CellContentClickgì chỉ xảy ra:
khi nội dung trong một ô được bấm
Vì bất kỳ lý do gì, tiêu đề cột cũng được coi là "nội dung" trong một ô, vì vậy chúng tôi vẫn phải kiểm tra phần bên dưới.
Liều dùng:
Vì vậy, đây là những gì bạn nên làm:
Đầu tiên, bỏ người gửi để nhập DataGridViewđể hiển thị các thuộc tính bên trong của nó tại thời điểm thiết kế. Bạn có thể sửa đổi loại trên tham số, nhưng điều đó đôi khi có thể khiến việc thêm hoặc xóa trình xử lý trở nên khó khăn.
Tiếp theo, để xem nếu một nút được nhấp, chỉ cần kiểm tra để đảm bảo rằng cột nâng sự kiện là loại DataGridViewButtonColumn. Vì chúng tôi đã chọn người gửi để nhập DataGridView, chúng tôi có thể lấy Columnsbộ sưu tập và chọn cột hiện tại bằng cách sử dụng e.ColumnIndex. Sau đó kiểm tra xem đối tượng đó có thuộc loại không DataGridViewButtonColumn.
Tất nhiên, nếu bạn cần phân biệt giữa nhiều nút trên mỗi lưới, thì bạn có thể chọn dựa trên tên hoặc chỉ mục của cột, nhưng đó không phải là kiểm tra đầu tiên của bạn. Luôn đảm bảo rằng một nút được nhấp trước và sau đó xử lý mọi thứ khác một cách thích hợp. Trong hầu hết các trường hợp bạn chỉ có một nút duy nhất cho mỗi lưới, bạn có thể nhảy ngay vào các cuộc đua.
Để tất cả chúng cùng nhau:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Cập nhật 1 - Sự kiện tùy chỉnh
Nếu bạn muốn có một chút niềm vui, bạn có thể thêm sự kiện của riêng mình để được nâng lên bất cứ khi nào một nút được nhấp vào DataGrid. Bạn không thể thêm nó vào DataGrid, mà không bị lộn xộn với tính kế thừa, v.v., nhưng bạn có thể thêm một sự kiện tùy chỉnh vào biểu mẫu của mình và kích hoạt nó khi thích hợp. Đó là một mã nhiều hơn một chút, nhưng nhược điểm là bạn đã tách ra những gì bạn muốn làm khi một nút được nhấp với cách xác định nếu một nút được nhấp.
Chỉ cần tuyên bố một sự kiện, nâng cao nó khi thích hợp và xử lý nó. Nó sẽ trông giống thế này:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Cập nhật 2 - Lưới mở rộng
Điều tuyệt vời là nếu chúng ta làm việc với một mạng lưới vừa làm những điều này cho chúng ta. Chúng tôi có thể trả lời câu hỏi ban đầu một cách dễ dàng : you've added a button to your DataGridView and you want to run some code when it's clicked. Đây là một cách tiếp cận mở rộng DataGridView. Nó có thể không có giá trị rắc rối khi phải cung cấp một điều khiển tùy chỉnh với mọi thư viện, nhưng ít nhất nó sử dụng tối đa mã được sử dụng để xác định nếu một nút được nhấp.
Chỉ cần thêm nó vào hội đồng của bạn:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
Đó là nó. Không bao giờ chạm vào nó một lần nữa. Đảm bảo DataGrid của bạn thuộc loại DataGridViewExtsẽ hoạt động chính xác như DataGridView. Ngoại trừ nó cũng sẽ đưa ra một sự kiện bổ sung mà bạn có thể xử lý như thế này:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
