đầu ra vbscript đến bàn điều khiển

Lệnh hoặc cách nhanh nhất để xuất kết quả ra bàn điều khiển bằng vbscript là gì?

Ý bạn là:

Wscript.Echo "Like this?"

Nếu bạn chạy nó bên dưới wscript.exe(trình xử lý mặc định cho tiện ích mở rộng .vbs, vậy bạn sẽ nhận được gì nếu nhấp đúp vào tập lệnh), bạn sẽ nhận được hộp thoại "MessageBox" với văn bản của mình trong đó. Nếu bạn chạy nó dưới cscript.exebạn sẽ nhận được đầu ra trong cửa sổ giao diện điều khiển của bạn.

Điều này đã được tìm thấy trên Dragon-IT Script và Code Rep Storage .

Bạn có thể làm điều này với những điều sau đây và tránh xa sự khác biệt của cscript / wscript và cho phép bạn có được đầu ra giao diện điều khiển giống như một tệp bó. Điều này có thể giúp nếu VBS gọi của bạn từ một tệp bó và cần làm cho nó trông liền mạch.

Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
stdout.WriteLine "This will go to standard output."
stderr.WriteLine "This will go to error output."

Bạn chỉ cần buộc cscript thay vì wscript. Tôi luôn luôn sử dụng mẫu này. Hàm ForceConsole () sẽ thực thi vbs của bạn thành cscript, ngoài ra bạn có bí danh đẹp để in và quét văn bản.

 Set oWSH = CreateObject("WScript.Shell")
 vbsInterpreter = "cscript.exe"

 Call ForceConsole()

 Function printf(txt)
    WScript.StdOut.WriteLine txt
 End Function

 Function printl(txt)
    WScript.StdOut.Write txt
 End Function

 Function scanf()
    scanf = LCase(WScript.StdIn.ReadLine)
 End Function

 Function wait(n)
    WScript.Sleep Int(n * 1000)
 End Function

 Function ForceConsole()
    If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
        oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
        WScript.Quit
    End If
 End Function

 Function cls()
    For i = 1 To 50
        printf ""
    Next
 End Function

 printf " _____ _ _           _____         _    _____         _     _   "
 printf "|  _  |_| |_ ___ ___|     |_ _ _ _| |  |   __|___ ___|_|___| |_ "
 printf "|     | | '_| . |   |   --| | | | . |  |__   |  _|  _| | . |  _|"
 printf "|__|__|_|_,_|___|_|_|_____|_____|___|  |_____|___|_| |_|  _|_|  "
 printf "                                                       |_|     v1.0"
 printl " Enter your name:"
 MyVar = scanf
 cls
 printf "Your name is: " & MyVar
 wait(5)

Tôi đã xem qua bài đăng này và quay lại một cách tiếp cận mà tôi đã sử dụng một thời gian trước đây tương tự như @ MadAntrax.

Sự khác biệt chính là nó sử dụng lớp VBScript do người dùng định nghĩa để bọc tất cả logic để chuyển sang CScript và xuất văn bản ra bàn điều khiển, do đó nó làm cho tập lệnh chính sạch hơn một chút.

Điều này giả định rằng mục tiêu của bạn là truyền phát đầu ra đến bàn điều khiển, thay vì xuất ra các hộp thông báo.

Lớp cCONSOLE ở bên dưới. Để sử dụng nó, bao gồm lớp hoàn chỉnh ở cuối tập lệnh của bạn, và sau đó khởi tạo nó ngay ở đầu tập lệnh. Đây là một ví dụ:

    Option Explicit

'// Instantiate the console object, this automatically switches to CSCript if required
Dim CONS: Set CONS = New cCONSOLE

'// Now we can use the Consol object to write to and read from the console
With CONS

    '// Simply write a line
     .print "CSCRIPT Console demo script"

     '// Arguments are passed through correctly, if present
     .Print "Arg count=" & wscript.arguments.count

     '// List all the arguments on the console log
     dim ix
     for ix = 0 to wscript.arguments.count -1
        .print "Arg(" & ix & ")=" & wscript.arguments(ix)
     next

     '// Prompt for some text from the user
     dim sMsg : sMsg = .prompt( "Enter any text:" )

     '// Write out the text in a box
     .Box sMsg

     '// Pause with the message "Hit enter to continue"
     .Pause

End With     




'= =========== End of script - the cCONSOLE class code follows here

Đây là mã cho lớp cCONSOLE

     CLASS cCONSOLE
 '= =================================================================
 '= 
 '=    This class provides automatic switch to CScript and has methods
 '=    to write to and read from the CSCript console. It transparently
 '=    switches to CScript if the script has been started in WScript.
 '=
 '= =================================================================

    Private oOUT
    Private oIN


    Private Sub Class_Initialize()
    '= Run on creation of the cCONSOLE object, checks for cScript operation


        '= Check to make sure we are running under CScript, if not restart
        '= then run using CScript and terminate this instance.
        dim oShell
        set oShell = CreateObject("WScript.Shell")

        If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
            '= Not running under CSCRIPT

            '= Get the arguments on the command line and build an argument list
            dim ArgList, IX
            ArgList = ""

            For IX = 0 to wscript.arguments.count - 1
                '= Add the argument to the list, enclosing it in quotes
                argList = argList & " """ & wscript.arguments.item(IX) & """"
            next

            '= Now restart with CScript and terminate this instance
            oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
            WScript.Quit

        End If

        '= Running under CScript so OK to continue
        set oShell = Nothing

        '= Save references to stdout and stdin for use with Print, Read and Prompt
        set oOUT = WScript.StdOut
        set oIN = WScript.StdIn

        '= Print out the startup box 
            StartBox
            BoxLine Wscript.ScriptName
            BoxLine "Started at " & Now()
            EndBox


    End Sub

    '= Utility methods for writing a box to the console with text in it

            Public Sub StartBox()

                Print "  " & String(73, "_") 
                Print " |" & Space(73) & "|"
            End Sub

            Public Sub BoxLine(sText)

                Print Left(" |" & Centre( sText, 74) , 75) & "|"
            End Sub

            Public Sub EndBox()
                Print " |" & String(73, "_") & "|"
                Print ""
            End Sub

            Public Sub Box(sMsg)
                StartBox
                BoxLine sMsg
                EndBox
            End Sub

    '= END OF Box utility methods


            '= Utility to center given text padded out to a certain width of text
            '= assuming font is monospaced
            Public Function Centre(sText, nWidth)
                dim iLen
                iLen = len(sText)

                '= Check for overflow
                if ilen > nwidth then Centre = sText : exit Function

                '= Calculate padding either side
                iLen = ( nWidth - iLen ) / 2

                '= Generate text with padding
                Centre = left( space(iLen) & sText & space(ilen), nWidth )
            End Function



    '= Method to write a line of text to the console
    Public Sub Print( sText )

        oOUT.WriteLine sText
    End Sub

    '= Method to prompt user input from the console with a message
    Public Function Prompt( sText )
        oOUT.Write sText
        Prompt = Read()
    End Function

    '= Method to read input from the console with no prompting
    Public Function Read()
        Read = oIN.ReadLine
    End Function

    '= Method to provide wait for n seconds
    Public Sub Wait(nSeconds)
        WScript.Sleep  nSeconds * 1000 
    End Sub

    '= Method to pause for user to continue
    Public Sub Pause
        Prompt "Hit enter to continue..."
    End Sub


 END CLASS

Có năm cách để xuất văn bản ra bàn điều khiển:

Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)

WScript.Echo "Hello"
WScript.StdOut.Write "Hello"
WScript.StdOut.WriteLine "Hello"
Stdout.WriteLine "Hello"
Stdout.Write "Hello"

WScript.Echo sẽ xuất ra bàn điều khiển nhưng chỉ khi tập lệnh được bắt đầu sử dụng cscript.exe. Nó sẽ xuất ra các hộp thông báo nếu bắt đầu sử dụng wscript.exe.

WScript.StdOut.Write và WScript.StdOut.WriteLine sẽ luôn xuất ra bàn điều khiển.

StdOut.Write và StdOut.WriteLine cũng sẽ luôn xuất ra console. Nó yêu cầu tạo thêm đối tượng nhưng nó nhanh hơn khoảng 10% so với WScript.Echo.