Lô Windows tương đương với lệnh shell Linux echo -nngăn chặn dòng mới ở cuối đầu ra là gì?

Ý tưởng là viết trên cùng một dòng trong một vòng lặp.

Sử dụng setvà /ptham số bạn có thể lặp lại mà không cần dòng mới:

C:\> echo Hello World
Hello World

C:\> echo|set /p="Hello World"
Hello World
C:\>

Nguồn

Sử dụng: echo | set /p=hoặc <NUL set /p=cả hai sẽ hoạt động để ngăn chặn dòng mới.

Tuy nhiên, điều này có thể rất nguy hiểm khi viết các tập lệnh nâng cao hơn khi kiểm tra ERRORLEVEL trở nên quan trọng vì cài đặt set /p=mà không chỉ định tên biến sẽ đặt ERRORLEVEL thành 1.

Một cách tiếp cận tốt hơn là chỉ sử dụng một tên biến giả như vậy:
echo | set /p dummyName=Hello World

Điều này sẽ tạo ra chính xác những gì bạn muốn mà không có bất kỳ thứ lén lút nào đang diễn ra trong nền vì tôi phải tìm ra cách khó khăn, nhưng điều này chỉ hoạt động với phiên bản đường ống; <NUL set /p dummyName=Hellovẫn sẽ nâng ERRORLEVEL lên 1.

Phương thức SET / P đơn giản có các hạn chế thay đổi đôi chút giữa các phiên bản Windows.

• Báo giá hàng đầu có thể bị tước

• Không gian trắng hàng đầu có thể bị tước

• Dẫn =đến một lỗi cú pháp.

Xem http://www.dostips.com/forum/viewtopic.php?f=3&t=4209 để biết thêm thông tin.

jeb đã đăng một giải pháp thông minh giúp giải quyết hầu hết các vấn đề tại văn bản đầu ra mà không có nguồn cấp dữ liệu, ngay cả với không gian hàng đầu hoặc = Tôi đã tinh chỉnh phương pháp để nó có thể in hoàn toàn bất kỳ chuỗi lô hợp lệ nào mà không cần dòng mới, trên bất kỳ phiên bản Windows nào từ XP trở đi. Lưu ý rằng :writeInitializephương thức chứa một chuỗi ký tự có thể không đăng tốt lên trang web. Một nhận xét được bao gồm mô tả chuỗi ký tự nên là gì.

Các phương thức :writevà :writeVarđược tối ưu hóa sao cho chỉ các chuỗi chứa các ký tự hàng đầu rắc rối được viết bằng phiên bản sửa đổi của phương thức COPY của jeb. Các chuỗi không rắc rối được viết bằng phương pháp SET / P đơn giản và nhanh hơn.

@echo off
setlocal disableDelayedExpansion
call :writeInitialize
call :write "=hello"
call :write " world!%$write.sub%OK!"
echo(
setlocal enableDelayedExpansion
set lf=^


set "str= hello!lf!world^!!!$write.sub!hello!lf!world"
echo(
echo str=!str!
echo(
call :write "str="
call :writeVar str
echo(
exit /b

:write  Str
::
:: Write the literal string Str to stdout without a terminating
:: carriage return or line feed. Enclosing quotes are stripped.
::
:: This routine works by calling :writeVar
::
setlocal disableDelayedExpansion
set "str=%~1"
call :writeVar str
exit /b


:writeVar  StrVar
::
:: Writes the value of variable StrVar to stdout without a terminating
:: carriage return or line feed.
::
:: The routine relies on variables defined by :writeInitialize. If the
:: variables are not yet defined, then it calls :writeInitialize to
:: temporarily define them. Performance can be improved by explicitly
:: calling :writeInitialize once before the first call to :writeVar
::
if not defined %~1 exit /b
setlocal enableDelayedExpansion
if not defined $write.sub call :writeInitialize
set $write.special=1
if "!%~1:~0,1!" equ "^!" set "$write.special="
for /f delims^=^ eol^= %%A in ("!%~1:~0,1!") do (
  if "%%A" neq "=" if "!$write.problemChars:%%A=!" equ "!$write.problemChars!" set "$write.special="
)
if not defined $write.special (
  <nul set /p "=!%~1!"
  exit /b
)
>"%$write.temp%_1.txt" (echo !str!!$write.sub!)
copy "%$write.temp%_1.txt" /a "%$write.temp%_2.txt" /b >nul
type "%$write.temp%_2.txt"
del "%$write.temp%_1.txt" "%$write.temp%_2.txt"
set "str2=!str:*%$write.sub%=%$write.sub%!"
if "!str2!" neq "!str!" <nul set /p "=!str2!"
exit /b


:writeInitialize
::
:: Defines 3 variables needed by the :write and :writeVar routines
::
::   $write.temp - specifies a base path for temporary files
::
::   $write.sub  - contains the SUB character, also known as <CTRL-Z> or 0x1A
::
::   $write.problemChars - list of characters that cause problems for SET /P
::      <carriageReturn> <formFeed> <space> <tab> <0xFF> <equal> <quote>
::      Note that <lineFeed> and <equal> also causes problems, but are handled elsewhere
::
set "$write.temp=%temp%\writeTemp%random%"
copy nul "%$write.temp%.txt" /a >nul
for /f "usebackq" %%A in ("%$write.temp%.txt") do set "$write.sub=%%A"
del "%$write.temp%.txt"
for /f %%A in ('copy /z "%~f0" nul') do for /f %%B in ('cls') do (
  set "$write.problemChars=%%A%%B    ""
  REM the characters after %%B above should be <space> <tab> <0xFF>
)
exit /b

Là một phụ lục cho câu trả lời của @ xmechanix, tôi nhận thấy thông qua việc viết nội dung vào một tệp:

echo | set /p dummyName=Hello World > somefile.txt

Rằng điều này sẽ thêm một khoảng trắng ở cuối chuỗi in , điều này có thể gây bất tiện, đặc biệt vì chúng tôi đang cố gắng tránh thêm một dòng mới (một ký tự khoảng trắng khác) vào cuối chuỗi.

May mắn thay, trích dẫn chuỗi được in, tức là sử dụng:

echo | set /p dummyName="Hello World" > somefile.txt

Sẽ in chuỗi mà không có bất kỳ ký tự dòng hoặc dấu cách ở cuối.

Một giải pháp cho khoảng trắng bị tước trong SET / P:

mẹo nhỏ là backspace char mà bạn có thể triệu tập trong trình soạn thảo văn bản EDIT cho DOS. Để tạo nó trong EDIT, nhấn ctrlP + ctrlH . Tôi sẽ dán nó ở đây nhưng trang web này không thể hiển thị nó. Mặc dù vậy, nó vẫn hiển thị trên Notepad (nó giống như một hình chữ nhật nhỏ màu đen với một vòng tròn màu trắng ở giữa)

Vì vậy, bạn viết này:

<nul set /p=.9    Hello everyone

Dấu chấm có thể là bất kỳ ký tự nào, chỉ có ở đó để nói với SET / P rằng văn bản bắt đầu từ đó, trước dấu cách và không phải ở " Xin chào ". " 9 " là một đại diện của char backspace mà tôi không thể hiển thị ở đây. Bạn phải đặt nó thay vì 9 và nó sẽ xóa " . ", Sau đó bạn sẽ nhận được điều này:

    Hello Everyone

thay vì:

Hello Everyone

Tôi hy vọng nó sẽ giúp

Bạn có thể xóa dòng mới bằng cách sử dụng "tr" từ gnuwin32 ( gói coreutils )

@echo off
set L=First line
echo %L% | tr -d "\r\n"
echo Second line
pause

Nhân tiện, nếu bạn đang thực hiện nhiều kịch bản, gnuwin32 là một mỏ vàng.

Đây là một phương pháp khác, nó sử dụng Powershell Write-Host có tham số -NoNewLine, kết hợp với start /bvà nó cung cấp cùng chức năng từ lô.

NoNewLines.cmd

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - ';Write-Host -NoNewLine 'Result 2 - ';Write-Host -NoNewLine 'Result 3 - '"
PAUSE

Đầu ra

Result 1 - Result 2 - Result 3 - Press any key to continue . . .

Cái này bên dưới hơi khác một chút, không hoạt động chính xác như OP muốn, nhưng thật thú vị vì mỗi kết quả ghi đè lên kết quả trước đó mô phỏng một bộ đếm.

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 2 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 3 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 4 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 5 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 6 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 7 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 8 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 9 - '"
PAUSE

Từ đây

<nul set /p =Testing testing

và cũng để lặp lại bắt đầu với không gian sử dụng

echo.Message goes here

Có lẽ đây là thứ bạn đang tìm kiếm, đó là một kịch bản trường học cũ ...: P

set nl=^& echo. 
echo %nl%The%nl%new%nl%line%nl%is%nl%not%nl%apparent%nl%throughout%nl%text%nl%
echo only in prompt.
pause

hoặc có thể bạn đang cố gắng thay thế một dòng hiện tại thay vì viết lên một dòng mới? bạn có thể thử nghiệm điều này bằng cách xóa "% bs%" sau dấu "." ký và cũng bằng cách tách ra "% bs%" khác sau "Thông báo mẫu".

for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "bs=%%a"
<nul set /p=.%bs%         Example message         %bs%
pause

Tôi thấy điều này thực sự thú vị bởi vì nó sử dụng một biến cho một mục đích khác với những gì nó dự định làm. như bạn có thể thấy "% bs%" đại diện cho một khoảng lùi. "% Bs%" thứ hai sử dụng khoảng trắng phía sau để thêm khoảng trắng sau "Thông báo ví dụ" để tách "đầu ra của lệnh tạm dừng" mà không thực sự thêm một ký tự hiển thị sau "Thông báo ví dụ". Tuy nhiên, điều này cũng có thể với một tỷ lệ phần trăm thông thường.

cw.exeTiện ích DIY (bảng điều khiển viết)

Nếu bạn không tìm thấy nó ngoài hộp, ngoài giá, bạn có thể DIY. Với cwtiện ích này, bạn có thể sử dụng mọi loại ký tự. Ít nhất, tôi muốn nghĩ như vậy. Hãy căng thẳng kiểm tra nó và cho tôi biết.

Công cụ

Tất cả bạn cần là .NET cài đặt , điều này rất phổ biến hiện nay.

Nguyên vật liệu

Một số ký tự gõ / sao chép-dán.

Các bước

1. Tạo .battập tin với nội dung sau.

/* >nul 2>&1

@echo off
setlocal

set exe=cw
for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*csc.exe"') do set "csc=%%v"

"%csc%" -nologo -out:"%exe%.exe" "%~f0"

endlocal
exit /b %errorlevel%

*/

using System;

namespace cw {
    class Program {
        static void Main() {
            var exe = Environment.GetCommandLineArgs()[0];
            var rawCmd = Environment.CommandLine;
            var line = rawCmd.Remove(rawCmd.IndexOf(exe),exe.Length).TrimStart('"');
            line = line.Length < 2 ? "\r" : line.Substring(2) ;
            Console.Write(line);
        }
    }
}

2. Chạy nó

3. Bây giờ bạn có một tiện ích 4KB đẹp để bạn có thể xóa .bat.

Ngoài ra, bạn có thể chèn mã này dưới dạng chương trình con trong bất kỳ lô nào, gửi kết quả .exeđến %temp%, sử dụng mã đó trong lô của bạn và xóa mã đó khi bạn hoàn tất.

Cách sử dụng

Nếu bạn muốn viết một cái gì đó mà không có dòng mới:
cw Whatever you want, even with "", but remember to escape ^|, ^^, ^&, etc. unless double-quoted, like in "| ^ &".

Nếu bạn muốn trở về xe ngựa (đi đến đầu dòng), hãy chạy ngay
cw

Vì vậy, hãy thử điều này từ dòng lệnh:

for /l %a in (1,1,1000) do @(cw ^|&cw&cw /&cw&cw -&cw&cw \&cw)

Tôi đã thực hiện một chức năng từ ý tưởng của @arnep:

echo | set / p = "Xin chào thế giới"

đây là:

:SL (sameline)
echo|set /p=%1
exit /b

Sử dụng nó với call :SL "Hello There"
tôi biết điều này không có gì đặc biệt nhưng tôi đã mất rất lâu để nghĩ về nó. Tôi nghĩ rằng tôi đã đăng nó ở đây.

Mẫu 1: Điều này hoạt động và tạo mã Thoát = 0. Đó là Tốt. Lưu ý "." , trực tiếp sau tiếng vang.

C: \ Users \ phife.dog \ gitrepose \ 1 \ repo_abc \ scripts #
@echo. | set / p JUNK_VAR = Đây là một thông báo được hiển thị giống như Linux echo -n sẽ hiển thị nó ... & echo% ERRORLEVEL%

Đây là một thông báo được hiển thị như Linux echo -n sẽ hiển thị nó ... 0

Mẫu 2: Điều này hoạt động nhưng tạo mã Thoát = 1. Điều đó là xấu. Xin lưu ý thiếu ".", Sau tiếng vang. Đó dường như là sự khác biệt.

C: \ Users \ phife.dog \ gitrepose \ 1 \ repo_abc \ scripts #
@echo | set / p JUNK_VAR = Đây là một thông báo được hiển thị giống như Linux echo -n sẽ hiển thị nó ... & echo% ERRORLEVEL%

Đây là một thông báo được hiển thị như Linux echo -n sẽ hiển thị nó ... 1

Lấy cảm hứng từ các câu trả lời cho câu hỏi này, tôi đã tạo một tập lệnh truy cập đơn giản, tiếp tục in giá trị tiến trình (0-100%) trên cùng một dòng (ghi đè lên tập lệnh trước đó). Có lẽ điều này cũng sẽ có giá trị cho những người khác đang tìm kiếm một giải pháp tương tự.

Ghi chú : Các *ký tự không in được, chúng phải được nhập bằng tổ hợp phím [ Alt+ Numpad 0+ Numpad 8], là backspaceký tự.

@ECHO OFF

FOR /L %%A in (0, 10, 100) DO (     
    ECHO|SET /P="****%%A%%"    
    CALL:Wait 1
)

GOTO:EOF

:Wait
SET /A "delay=%~1+1"
CALL PING 127.0.0.1 -n %delay% > NUL
GOTO:EOF

Tôi tin rằng không có lựa chọn như vậy. Ngoài ra, bạn có thể thử điều này

set text=Hello
set text=%text% world
echo %text%

Bạn có thể chặn dòng mới bằng cách sử dụng lệnh set / p. Lệnh set / p không nhận ra một khoảng trắng, để bạn có thể sử dụng dấu chấm và ký tự backspace để làm cho nó nhận ra nó. Bạn cũng có thể sử dụng một biến làm bộ nhớ và lưu trữ những gì bạn muốn in trong đó, để bạn có thể in biến thay vì câu. Ví dụ:

@echo off
setlocal enabledelayedexpansion
for /f %%a in ('"prompt $H & for %%b in (1) do rem"') do (set "bs=%%a")
cls
set "var=Hello World! :)"
set "x=0"

:loop
set "display=!var:~%x%,1!"
<nul set /p "print=.%bs%%display%"
ping -n 1 localhost >nul
set /a "x=%x% + 1"
if "!var:~%x%,1!" == "" goto end
goto loop

:end
echo.
pause
exit

Bằng cách này, bạn có thể in bất cứ thứ gì mà không cần một dòng mới. Tôi đã tạo chương trình để in từng ký tự một, nhưng bạn cũng có thể sử dụng các từ thay vì các ký tự bằng cách thay đổi vòng lặp.

Trong ví dụ trên tôi đã sử dụng "enableelayedExansion" để lệnh set / p không nhận ra "!" ký tự và in một dấu chấm thay vì đó. Tôi hy vọng rằng bạn không sử dụng dấu chấm than "!" ;)

Câu trả lời muộn ở đây, nhưng đối với bất kỳ ai cần viết các ký tự đặc biệt cho một dòng duy nhất tìm thấy câu trả lời của dbenham dài khoảng 80 dòng và các tập lệnh có thể bị hỏng (có lẽ do đầu vào của người dùng) trong các giới hạn của việc sử dụng đơn giản set /p, Có lẽ dễ dàng nhất để ghép .bat hoặc .cmd của bạn với một ngôn ngữ C ++ hoặc C được biên dịch và sau đó chỉ couthoặc printfcác ký tự. Điều này cũng sẽ cho phép bạn dễ dàng viết nhiều lần vào một dòng nếu bạn đang hiển thị một loại thanh tiến trình hoặc thứ gì đó sử dụng các ký tự, như OP rõ ràng là.