Làm thế nào để sử dụng sort trên một lệnh in awk?

Tôi có một vài lệnh trong một kịch bản awk tôi đang viết:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Đầu ra nào:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Làm cách nào tôi có thể sử dụng sortlệnh trong tập lệnh awk của mình để sắp xếp người chơi và số của họ CHỈ?

bạn có thể thêm | sort -k2vào lệnh của bạn. Điều này sẽ sắp xếp theo thứ tự abc dựa trên cột thứ hai.

Thí dụ:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

kết quả trong

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Mặc dù tôi không khuyến nghị điều đó (với sự đơn giản tương đối của đường ống kết quả thông qua sortlệnh bên ngoài ), bạn có thể thực hiện điều này ít nhất với các phiên bản gần đây của GNU awk (ít nhất là 4.0 IIRC), như được mô tả tại Sắp xếp các giá trị và chỉ số mảng với gawk

Đây là cách bạn có thể thực hiện nó, giả sử bạn có dữ liệu trong một mảng kết hợp trong đó chỉ mục Firstname Lastname. Trước tiên, bạn cần xác định chức năng so sánh tùy chỉnh phân tách chỉ mục, trước tiên so sánh Lastnamesau đó (dưới dạng ngắt kết nối) trên Firstnameví dụ:

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Bây giờ bạn có thể sử dụng PROCINFO["sorted_in"]phương pháp sắp xếp mảng được đề cập trong các nhận xét của @zwets

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Đặt nó lại với nhau

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

Kiểm tra:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Trong các phiên bản awk ít hơn hoặc cũ hơn, cách tốt nhất của bạn có thể là lưu trữ dữ liệu được lập chỉ mục Lastname Firstnamethay vào đó, sắp xếp theo thông thường asorti, sau đó phân tách và trao đổi các trường của các chỉ mục khi bạn duyệt qua mảng để in:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Để sortchỉ bằng trường thứ hai được phân tách khoảng trắng, sử dụng khóa -k2,2:

... | sort -k2,2

theo mặc định sort, việc sắp xếp từ vựng.

Lưu ý rằng, nếu bạn không đề cập đến trường cuối cùng cho khóa sắp xếp, tức là nếu bạn chỉ sử dụng -k2thì bạn có thể không nhận được kết quả mong muốn vì điều này sẽ sorttheo tất cả các trường bắt đầu từ giây.

Cũng kiểm tra man sort.

Thử

awk -f myscript.awk | sort -k2

Trong đó myscript.awk chứa các lệnh awk hoàn toàn.

Nếu tập lệnh thực tế của bạn là tập lệnh shell, bạn có một số tùy chọn bao gồm

• Đầu ra ống thông qua sắp xếp. ./myscript.bash | sort -k2

• Viết lại mã dưới dạng một hàm bên trong tập lệnh
  Thay vì

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Làm

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Nhưng lưu ý rằng bạn cũng có thể áp dụng sắp xếp cho cấu trúc do ... thực hiện thay vì thực hiện một chức năng.

    do
       echo $i
    done | sort

Để sắp xếp dữ liệu của bạn để in:

• Giả sử bạn muốn in trường thứ 2 (tách khoảng trắng) sử dụng:

  awk '{print $2}' data.txt | sort
  

  ví dụ:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Nếu bạn muốn in toàn bộ data.txtnhưng được sắp xếp trên cột 2, thì:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Sử dụng logic này trong yêu cầu của bạn.

Bạn có thể sử dụng man sortcho các tính năng thú vị hơn của sort.

những gì về bên dưới:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

Nó hoạt động khi tôi thử nghiệm.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

Để sắp xếp đầu ra cho một tệp:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}