Đếm số dòng giữa

Tôi muốn đếm các dòng giữa "X" s. Đây chỉ là một ví dụ; Tôi phải áp dụng mã cho một kết quả sinh học phức tạp. Tôi sẽ rất biết ơn nếu bạn có thể đề xuất một số lệnh, tốt nhất là sử dụng awk, grephoặc sednhư tôi quen thuộc với những người.

Thí dụ:

X
Y
Y
Y
X
Y
Y
Y
Y
X
Y
X

Sản phẩm chất lượng:

3
4
1

Với awk:

$ awk '!/X/{count++}/X/{print count; count = 0}' input

3
4
1

Tăng một số lượng cho mỗi dòng không chứa X; in và thiết lập lại số đếm cho các dòng chứa X.

$ awk '/X/ && prev{print NR-prev-1} /X/{prev=NR}' file
3
4
1

Làm thế nào nó hoạt động:

Awk ngầm đọc qua các tệp đầu vào từng dòng.

• /X/ && prev{print NR-prev-1}

  Đối với bất kỳ dòng nào có chứa Xvà nếu trước đây chúng ta đã gán một giá trị prev, sau đó in ra số dòng hiện tại NR, trừ prevđi một giá trị.

• /X/{prev=NR}

  Đối với bất kỳ dòng nào có chứa X, đặt biến prevthành số dòng hiện tại , NR.

Một awkcách tiếp cận đơn giản khác hoạt động trên dữ liệu mẫu của OP và nếu Xkhông có trong các X đầu tiên hoặc thậm chí lặp lại.

awk -v RS='X' 'NF{print NF}' infile

Trên đây là chính xác khi chỉ có một trường trong mỗi dòng với FS mặc định bất kỳ khoảng trắng nào , nếu không bên dưới được sửa đổi trong trường hợp chung để đếm theo dòng . Bạn có thể nhập MẪU của bạn thay cho X ở đó.

awk -F'\n' -v RS='X' 'NF>2{print NF-2}'

Đầu vào mẫu:

X
Y YYY Y
YY
YY Y YY YY Y Y
X
Y Y Y
X
Y
Y
X
X

Đầu ra là:

3
1
2

Hầu hết các câu trả lời ở đây khớp với nội dung của dòng được tính bằng các biểu thức thông thường được nhúng vào chương trình Awk. Nếu bạn cần khớp các dòng với nội dung có thể chứa các ký tự đặc biệt (với biểu thức Awk hoặc biểu thức chính quy), tốt hơn là thực sự so sánh các chuỗi cho đẳng thức. Do đó, tôi đề xuất kịch bản Awk sau đây như là một biến thể của câu trả lời của muru :

BEGIN {
    count = 0;
}

{
    if ($0 == needle) {
        if (count) {
            print count;
            count = 0;
        }
    } else {
        count++;
    }
}

Lưu trữ dưới dạng tệp văn bản, ví dụ: count-rows.awkvà gọi nó như sau:

awk -f count-rows.awk -v needle=X input

Bạn có thể điều chỉnh giá trị needletheo ý thích của bạn. Ưu điểm của phương pháp này là bạn có thể gọi chương trình từ tập lệnh shell với giá trị tùy ý needlemà không thoát khỏi các vấn đề:

awk -f count-rows.awk -v needle="$needle" input