Xóa tất cả các bản sao liên tiếp

Tôi có một tập tin trông như thế này.

Move to 230.00
Hold
Hold
Hold
Hold
Hold
Hold
Move to 00.00
Hold 
Hold 
Hold 
Hold 
Hold 
FooBar
Hold 
Spam
Hold

Tôi muốn nó trông như thế này:

Move to 230.00
Hold
Move to 00.00
Hold 
FooBar
Hold
Spam
Hold

Tôi chắc chắn phải có một cách mà vim có thể nhanh chóng làm điều này, nhưng tôi hoàn toàn không thể quấn lấy đầu mình. Đây có phải là vượt quá sức mạnh của macro, và cần vimscript?

Ngoài ra, sẽ ổn nếu tôi phải áp dụng cùng một macro cho từng khối "Giữ". Nó không phải là một macro duy nhất có được toàn bộ tệp, mặc dù điều đó sẽ rất tuyệt vời.

Tôi nghĩ lệnh sau sẽ hoạt động:

 :%s/^\(.*\)\(\n\1\)\+$/\1/

Giải trình :

Chúng tôi sử dụng lệnh thay thế trên toàn bộ tệp để thay đổi patternthànhstring :

:%s/pattern/string/

Đây patternlà ^\(.*\)\(\n\1\)\+$vàstring là \1.

pattern có thể được chia nhỏ như thế này:

^\(subpattern1\)\(subpattern2\)\+$

^ và $ khớp tương ứng một đầu dòng và một cuối dòng.

\(và \)được sử dụng để gửi kèm theo subpattern1để chúng ta có thể tham khảo nó sau bằng số đặc biệt \1.
Chúng cũng được sử dụng để đính kèmsubpattern2 để chúng ta có thể lặp lại 1 hoặc nhiều lần với bộ định lượng \+.

subpattern1là .*
.một metacharacter phù hợp với bất kỳ ký tự nào ngoại trừ dòng mới và *là một bộ định lượng phù hợp với ký tự cuối cùng 0, 1 hoặc nhiều lần.
Vì vậy, .*phù hợp với bất kỳ văn bản không chứa dòng mới.

subpattern2là \n\1
\nphù hợp với một dòng sản phẩm mới và \1phù hợp với văn bản tương tự mà được kết hợp bên trong đầu tiên \(,\) mà ở đây là subpattern1.

Vì vậy, patterncó thể được đọc như thế này:
một dòng bắt đầu ( ^) theo sau bởi bất kỳ văn bản nào không chứa dòng mới ( .*) theo sau là một dòng mới ( \n) sau đó cùng một văn bản ( \1), hai dòng sau được lặp lại một hoặc nhiều lần ( \+) và cuối cùng là kết thúc của dòng ( $) .

Bất cứ nơi nào pattern được khớp (một khối các dòng giống hệt nhau), lệnh thay thế sẽ thay thế nó stringở đây \1(dòng đầu tiên của khối).

Nếu bạn muốn xem khối dòng nào sẽ bị ảnh hưởng mà không thay đổi bất cứ điều gì trong tệp của mình, bạn có thể bật hlsearchtùy chọn và thêm ncờ thay thế ở cuối lệnh:

:%s/^\(.*\)\(\n\1\)\+$/\1/n

Để kiểm soát chi tiết hơn, bạn cũng có thể yêu cầu xác nhận trước khi thay đổi từng khối dòng bằng cách thêm ccờ thay thế:

:%s/^\(.*\)\(\n\1\)\+$/\1/c

Để biết thêm thông tin về các lệnh đọc thay :help :s,
cho những lá cờ thay :help s_flags,
cho metacharacters khác nhau và quantifiers đọc :help pattern-atoms,
và cho biểu thức thông thường trong vim đọc này .

Chỉnh sửa: Wildcard đã khắc phục sự cố trong lệnh bằng cách thêm một $ở cuối pattern.

Ngoài ra BloodGain có phiên bản ngắn hơn và dễ đọc hơn của cùng một lệnh.

Hãy thử như sau:

:%s;\v^(.*)(\n\1)+$;\1;

Như với câu trả lời của saginaw , điều này sử dụng lệnh: thay thế của Vim. Tuy nhiên, nó tận dụng một vài tính năng bổ sung để cải thiện khả năng đọc:

1. Vim cho phép chúng tôi sử dụng bất kỳ ký tự ASCII không chữ và số nào ngoại trừ dấu gạch chéo ngược ( \ ), trích dẫn kép ( " ) hoặc ống ( | ) để phân chia văn bản khớp / thay thế / cờ của chúng tôi. Ở đây, tôi đã chọn dấu chấm phẩy ( ; ), nhưng bạn có thể chọn cái khác
2. Vim cung cấp các cài đặt "ma thuật" cho các biểu thức thông thường, để các ký tự được hiểu theo nghĩa đặc biệt của chúng thay vì yêu cầu thoát dấu gạch chéo ngược. Điều này rất hữu ích để giảm mức độ chi tiết và bởi vì nó phù hợp hơn so với mặc định "danh nghĩa". Bắt đầu với \vnghĩa là "rất kỳ diệu" hoặc tất cả các ký tự ngoại trừ chữ và số ( A-z0-9 ) và dấu gạch dưới ( _ ) có ý nghĩa đặc biệt.

Ý nghĩa của các thành phần là:

% cho toàn bộ tập tin

S thay thế

; bắt đầu chuỗi thay thế

\ v "rất kỳ diệu"

^ đầu dòng

(. *) 0 hoặc nhiều hơn bất kỳ ký tự nào (nhóm 1)

(\ n \ 1) + dòng mới theo sau (văn bản khớp nhóm 1), 1 lần trở lên (nhóm 2)

$ end of line (hoặc trong trường hợp này, nghĩ rằng ký tự tiếp theo phải là một dòng mới )

; bắt đầu thay thế chuỗi

\ 1 nhóm 1 khớp văn bản

; kết thúc lệnh hoặc bắt đầu cờ

Nếu bạn muốn xóa TẤT CẢ các dòng giống hệt nhau, không chỉ Hold, bạn có thể thực hiện dễ dàng với bộ lọc bên ngoài từ bên trongvim :

:%!uniq (trong môi trường Unix).

Nếu bạn muốn làm điều đó trực tiếp trong vim , nó thực sự rất khó khăn. Tôi nghĩ rằng có một cách, nhưng đối với trường hợp chung, rất khó để làm cho nó hoạt động 100% và tôi chưa tìm ra tất cả các lỗi.

Tuy nhiên, đối với trường hợp cụ thể này, vì bạn có thể thấy rằng dòng tiếp theo không trùng lặp không bắt đầu với cùng một ký tự, bạn có thể sử dụng:

:+,./^[^H]/-d

Có +nghĩa là dòng sau dòng hiện tại. Các . đề cập đến dòng hiện tại. Các/^[^H]/- nghĩa là dòng trước ( -) dòng tiếp theo không bắt đầu bằng H.

Sau đó d là xóa.

Câu trả lời dựa trên Vim:

:%s/\(^.*\n\)\1\{1,}/\1

= Thay thế mỗi dòng theo sau nó ít nhất một lần , bằng cùng một dòng.

Một lần nữa, giả sử Vim 7.4.218 trở lên:

function! s:Uniq(line1, line2)
    let cursor = getcurpos()
    let lines = uniq(getline(a:line1, a:line2))
    if setline(a:line1, lines) == 0 && len(lines) <= a:line2 - a:line1
        silent execute (a:line1 + len(lines)) . ',' . a:line2 . 'd _'
    endif
    call setpos('.', cursor)
endfunction

command! -range=% Uniq call <SID>Uniq(<line1>, <line2>)

Điều này không nhất thiết phải tốt hơn so với các giải pháp khác, mặc dù.

Đây là một giải pháp dựa trên một vim (golf) cũ (2003) của Preben Gulberg và Piet Delport.

• Đó là gốc rễ nằm ở %g/^\v(.*)\n\1$/d
• Không giống như các giải pháp khác, nó đã được gói gọn trong một hàm vì vậy, nó không sửa đổi thanh ghi tìm kiếm, cũng như thanh ghi không tên.
• Và nó cũng đã được gói gọn trong một lệnh để đơn giản hóa việc sử dụng nó:
  • :Uniq(tương đương với :%Uniq),
  • :1,Uniq (từ khi bắt đầu bộ đệm đến dòng hiện tại),
  • trực quan chọn dòng + hit :Uniq<cr>(mở rộng bằng vim vào :'<,'>Uniq)
  • v.v ( :h range)

Đây là mã:

command! -range=% -nargs=0 Uniq <line1>,<line2>call s:EmuleUniq()

function! s:EmuleUniq() range
  let l1 = a:firstline
  let l2 = a:lastline
  if l1 < l2
    " Note the "-" to avoid spilling over the end of the range
    " Note also the use of ":delete", along with the black hole register "_"
    silent exe l1.','l2.'-g/^\(.*\)\n\1$/d _'

    call histdel('search', -1)          " necessary
    " let @/ = histget('search', -1)    " useless within a function
  endif
endfunction

Lưu ý: lần thử đầu tiên của họ là:

" Version1 from: Preben 'Peppe' Guldberg <peppe {at} xs4all {dot} nl>
" silent exe l1 . ',' . (l2 - 1) . 's/^\(.*\)\%(\n\%<' . (l2 + 1)
      " \ . 'l\1$\)\+/\1/e'

" Version from: Piet Delport <pjd {at} 303.za {dot} net>
" silent exe l1.','l2.'g/^\%<'.l2.'l\(.*\)\n\1$/d'